How to print everything between two patterns using awk

Question

I can print everything between two patterns with this awk command:

awk '/'$1'/{a=1} a; /PATTERN2/{a=0}' ~/the/path/to/file.txt

What I need is to print everything between and include PATTERN1 and everything before PATTERN2 (which is always a line that starts with #.

Actually the patterns are hashtags like #france and #germany.

For example the file contains:

#france
France is a European country.
It's capital city is Paris.
One of its biggest cities is Lyon.

#germany
Germany is a European country.
It's capital city is Berlin.
One of its biggest cities is Munich.

What I want to be printed after calling #france:

#france
France is a European country.
It's capital city is Paris.
One of its biggest cities is Lyon.

Also it would be great if I can show the pattern in another color like blue or red.

Btw.: [How to match a pattern given in a variable in awk?](https://stackoverflow.com/q/39384283/3776858) — Cyrus, Jan 23 '22 at 20:09
Please read [how-do-i-use-shell-variables-in-an-awk-script](https://stackoverflow.com/questions/19075671/how-do-i-use-shell-variables-in-an-awk-script) and [how-do-i-find-the-text-that-matches-a-pattern](https://stackoverflow.com/questions/65621325/how-do-i-find-the-text-that-matches-a-pattern). — Ed Morton, Jan 23 '22 at 20:27

score 2 · Answer 1 · answered Jan 23 '22 at 20:37

If there is always blank line between entries you might harness paragraph mode of GNU AWK by setting RS to empty string, let file.txt content be

#france
France is a European country.
It's capital city is Paris.
One of its biggest cities is Lyon.

#germany
Germany is a European country.
It's capital city is Berlin.
One of its biggest cities is Munich.

then

awk 'BEGIN{RS=""}/^#france/' file.txt

output

#france
France is a European country.
It's capital city is Paris.
One of its biggest cities is Lyon.

Explanation: RS="" causes GNU AWK to treat paragraphs as rows. I simply filter rows which starts with (^) #france.

(tested in GNU Awk 5.0.1)

dawg · Accepted Answer · 2022-01-24T17:51:59.953

You can use the pattern of setting a flag based on matching the section you want to print:

awk -v cc="#france" '/^#/{f=($1==cc)} f' file
#france
France is a European country.
It's capital city is Paris.
One of its biggest cities is Lyon.

Or:

awk -v cc="#germany" '/^#/{f=($1==cc)} f' file
#germany
Germany is a European country.
It's capital city is Berlin.
One of its biggest cities is Munich.

This will never start printing if there is not a match, and it only stops printing when another #hashtag is encountered.

How can I colorize the pattern?

You would use ANSI Escape Codes as in This Post. This is dependent if your terminal setup supports ANSI codes. Most do.

Example:

awk -v cc="#germany" '/^#/{
    f=($1==cc)
    if (f) printf("\033[0;31m%s\033[0m\n", $0)
    next 
    } 
    f' file

Prints (on my terminal):

#germany                             # red on black
Germany is a European country.       # green on black...
It's capital city is Berlin.         # green is the default color
One of its biggest cities is Munich.

Thanks, It works well. How can I colorize the pattern? e.g: ```#france``` — sof31, Jan 24 '22 at 17:02

score 1 · Answer 3 · answered Jan 26 '22 at 00:17

1

With your shown samples only, you can try following awk code. Where I am using RS(record separator) as paragraph mode and checking if line starts from particular string then print that whole para.

awk -v RS="" '$0~/^#france\n/' Input_file

answered Jan 26 '22 at 00:17

RavinderSingh13

130,504
14
57
93

How to print everything between two patterns using awk

3 Answers3