Edit: Since I changed the question title to "...different pointtypes...", I should show how to do it with multiple columns and different pointtypes.
The data of multiple columns is interpolated along the path and appended to the datablock $DashMultipleCols as (sub-)blocks which can later be addressed via index. I leave it up to you to decide whether solid/dash/dotted or plus/circle/triangle is easier to distinguish.
The following example creates a datablock with equidistant points along a given path.
for illustration some random test data is created with 1 x-column and 3 y-columns
for comparison the first graph is with solid, dashed and dotted lines. To my opinion the lines can be well distinguished, but you asked for "dashing" with a symbol.
for the second plot the data of columns 2,3,4 is "dashed" with the pointtypes 1,6,8, respectively.
the distance between the symbols is set by a variable, here: Dist = 8
in order to get a visually equal distribution, coordinate conversions from x,y to pixel coordinates and reverse are used. For this, the gnuplot variables GPVAL... are used which are available after plotting. That's why it is necessary to plot twice. The command pause -1 can be removed.
this works for linear axes (would need adjustment for logarithmic axes)
Your data is timedata. The code needs to be adjusted accordingly.
Code: (tested with wxt terminal)
### "dashing" with symbols equidistantly along a path
reset session
# create some random test data
set print $Data
x0 = 0
y0 = y1 = y2 = 100
do for [i=1:10] {
print sprintf("%g %g %g %g", x0=x0+int(rand(0)*10)+5, y0=y0+int(rand(0)*10)-5, y1=y1+int(rand(0)*10)-5, y2=y2+int(rand(0)*10)-5)
}
set print
set key top left Left reverse
# plot to get the GPVAL_ ... values
plot $Data u 1:2 w l dt 1 lc "black" ti "Column 2, solid", \
'' u 1:3 w l dt 2 lc "black" ti "Column 3, dashed", \
'' u 1:4 w l dt 3 lc "black" ti "Column 4, dotted"
# store GPVAL parameters after plot in variables
txmin = GPVAL_TERM_XMIN
txmax = GPVAL_TERM_XMAX
tymin = GPVAL_TERM_YMIN
tymax = GPVAL_TERM_YMAX
xmin = GPVAL_X_MIN
xmax = GPVAL_X_MAX
ymin = GPVAL_Y_MIN
ymax = GPVAL_Y_MAX
# x,y to pix and pix to x,y coordinate conversion
XtoPix(x) = txmin + real(x-xmin) *(txmax-txmin)/( xmax- xmin)
YtoPix(y) = tymin + real(y-ymin) *(tymax-tymin)/( ymax- ymin)
PixToX(scrx) = xmin + real(scrx-txmin)*( xmax- xmin)/(txmax-txmin)
PixToY(scry) = ymin + real(scry-tymin)*( ymax- ymin)/(tymax-tymin)
# get lengths and angles in pixel coordinates
set angle degrees
Length(x0,y0,x1,y1) = sqrt((x1-x0)**2 + (y1-y0)**2)
Angle(x0,y0,x1,y1) = (_dx=x1-x0, _dy=y1-y0, _L=sqrt(_dx**2 + _dy**2), _L==0 ? NaN : \
(_dy>=0 ? acos(_dx/_L) : 360-acos(_dx/_L) ))
colX = 1
colsY = "2 3 4" # multiple y-columns
do for [colY in colsY] {
set table $LaA # table for length and angles
Total = 0
plot x1=y1=NaN $Data u (x0=x1,x1=XtoPix(column(colX)),x0):\
(y0=y1,y1=YtoPix(column(int(colY))),y0):\
(L=Length(x0,y0,x1,y1)):(L==L ? Total=Total+L : 0, Angle(x0,y0,x1,y1)) w table
unset table
X0(n) = real(word($LaA[n],1))
Y0(n) = real(word($LaA[n],2))
SegLength(n) = real(word($LaA[n],3))
SegAngle(n) = real(word($LaA[n],4))
# create equidistant datapoints along path
set print $DashSingleCol
Dist = 8 # Distance between symbols
N = floor(Total/Dist)
idx = 2
L0 = 0
L = SegLength(idx)
do for [i=0:N] {
R = i*Dist
while (L-R<0) {
L0 = L
idx = idx + 1
L = L + SegLength(idx)
}
print sprintf("%g %g", PixToX(X0(idx)+(R-L0)*cos(SegAngle(idx))), \
PixToY(Y0(idx)+(R-L0)*sin(SegAngle(idx))))
}
set print
set print $DashMultipleCols append
print $DashSingleCol
print "\n\n"
set print
}
pause -1
mySymbol(n) = int(word("1 6 8",n))
plot for [i=1:words(colsY)] $DashMultipleCols u 1:2:(mySymbol(i)) index i-1 \
w p pt mySymbol(i) ps 0.6 lc "black" ti sprintf("Column %s, Symbol %d",word(colsY,i),mySymbol(i))
### end of code
Result:
Addition: Code adapted for time format
The time in gnuplot is nothing else than seconds passed since Jan 1st, 1970 00:00:00. If you enter in the gnuplot console print time(0) (which is the current time) you will get something like 1646757721, so about 1.6 billion seconds have passed since then until today.
The main differences and things to keep in mind compared to the above code:
- define your specific time format, e.g.
myTimeFmt = "%Y %b %d"
- with this time format and the spaces inbetween, your data will be in columns 4,5, and 6.
- for plotting the data the first time you use, e.g.
plot $Data u (timecolumn(1,myTimeFmt)):4 w l
- for the length and angle table (
$LaA) you also have to use columns 4,5,6 and timecolumn() as well, i.e. plot x1=y1=NaN $Data u (x0=x1,x1=XtoPix(timecolumn(colX,myTimeFmt)),x0)
- for creating the datablock
$DashSingleCol you have to force the format for the time to be "%.0f" i.e. print sprintf("%.0f %g", PixToX(X0(idx)+(R-L0)*cos(SegAngle(idx))). Otherwise, with "%g" gnuplot would write a floating point number with exponent but only 6 digits, e.g. 1.64676e+09 which would be unwanted truncation or rounding.
- for plotting
$DashMultipleCols you can simply use u 1:2 because the time is already in seconds and does not have to be changes via timecolumn().
I hope this additional code and the explanations will help you to "dash" your data with different symbols.
Code:
### "dashing" with symbols equidistantly along a path (with timedata)
reset session
myTimeFmt = "%Y %b %d"
# create some random test data
set print $Data
t0 = time(0)
y0 = y1 = y2 = 10
SecsPerDay = 24*3600 # seconds per day
do for [i=1:10] {
t0=t0+int(rand(0)*10*SecsPerDay)+5*SecsPerDay
print sprintf("%s %g %g %g", strftime(myTimeFmt,t0), \
y0=y0+int(rand(0)*10)-5, y1=y1+int(rand(0)*10)-5, y2=y2+int(rand(0)*10)-5)
}
set print
set key top left Left reverse
# plot to get the GPVAL_ ... values
set format x "%b %01d\n%Y" timedate
plot $Data u (timecolumn(1,myTimeFmt)):4 w l dt 1 lc "black" ti "Column 4, solid", \
'' u (timecolumn(1,myTimeFmt)):5 w l dt 2 lc "black" ti "Column 5, dashed", \
'' u (timecolumn(1,myTimeFmt)):6 w l dt 3 lc "black" ti "Column 6, dotted"
# store GPVAL parameters after plot in variables
txmin = GPVAL_TERM_XMIN
txmax = GPVAL_TERM_XMAX
tymin = GPVAL_TERM_YMIN
tymax = GPVAL_TERM_YMAX
xmin = GPVAL_X_MIN
xmax = GPVAL_X_MAX
ymin = GPVAL_Y_MIN
ymax = GPVAL_Y_MAX
# x,y to pix and pix to x,y coordinate conversion
XtoPix(x) = txmin + real(x-xmin) *(txmax-txmin)/( xmax- xmin)
YtoPix(y) = tymin + real(y-ymin) *(tymax-tymin)/( ymax- ymin)
PixToX(scrx) = xmin + real(scrx-txmin)*( xmax- xmin)/(txmax-txmin)
PixToY(scry) = ymin + real(scry-tymin)*( ymax- ymin)/(tymax-tymin)
# get lengths and angles in pixel coordinates
set angle degrees
Length(x0,y0,x1,y1) = sqrt((x1-x0)**2 + (y1-y0)**2)
Angle(x0,y0,x1,y1) = (_dx=x1-x0, _dy=y1-y0, _L=sqrt(_dx**2 + _dy**2), _L==0 ? NaN : \
(_dy>=0 ? acos(_dx/_L) : 360-acos(_dx/_L) ))
colX = 1
colsY = "4 5 6" # multiple y-columns
do for [colY in colsY] {
set table $LaA # table for length and angles
Total = 0
plot x1=y1=NaN $Data u (x0=x1,x1=XtoPix(timecolumn(colX,myTimeFmt)),x0):\
(y0=y1,y1=YtoPix(column(int(colY))),y0):\
(L=Length(x0,y0,x1,y1)):(L==L ? Total=Total+L : 0, Angle(x0,y0,x1,y1)) w table
unset table
X0(n) = real(word($LaA[n],1))
Y0(n) = real(word($LaA[n],2))
SegLength(n) = real(word($LaA[n],3))
SegAngle(n) = real(word($LaA[n],4))
# create equidistant datapoints along path
set print $DashSingleCol
Dist = 8 # Distance between symbols
N = floor(Total/Dist)
idx = 2
L0 = 0
L = SegLength(idx)
do for [i=0:N] {
R = i*Dist
while (L-R<0) {
L0 = L
idx = idx + 1
L = L + SegLength(idx)
}
print sprintf("%.0f %g", PixToX(X0(idx)+(R-L0)*cos(SegAngle(idx))), \
PixToY(Y0(idx)+(R-L0)*sin(SegAngle(idx))))
}
set print
set print $DashMultipleCols append
print $DashSingleCol
print "\n\n"
set print
}
pause -1
mySymbol(n) = int(word("1 6 8",n))
plot for [i=1:words(colsY)] $DashMultipleCols u 1:2:(mySymbol(i)) index i-1 \
w p pt mySymbol(i) ps 0.6 lc "black" ti sprintf("Column %s, pointtype %d",word(colsY,i),mySymbol(i))
### end of code
Result:
