With starting command prompt with cmd /e:off or using setlocal disableExtensions (in a batch file) or excluding them through the registry value HKEY_CURRENT_USER\Software\Microsoft\Command Processor\EnableExtensions (by setting the value to 0) the feature called "extensions" is disabled (turned on by default).
What are the changes that this causes?
Turning off extensions affects some built-in environment variables and some internal for the command prompt commands. I've never seen full list of non-working variables ,though the internal commands are more or less well documented - but never put in a list together.
I. I'll start with the variables:
%CD% is not working. But surprisingly %__CD__% works though it sets additional backslash at the end.
%CMDEXTVERSION% - logical at some degree as the command prompt is reduced only to its earlier versions
%CMDCMDLINE% - command line could be retrieved with some external tools that will give you information about the current PID.
%ERRORLEVEL% - as alternative %=ExitCode% can be used. Also %=ExitCodeAscii% if the exit code is above 32. IF ERRORLEVEL also still works.
%DATE% and %TIME% - though in disabled extensions mode you won't be able to assign the current date to a variable there are at least a lot of ways to display it.
%RANDOM%
%HighestNumaNodeNumber% - this was the biggest surprise for me as this variable was introduced in the newer versions of Windows when the support for multicore processors was added. It is highly related to the /NODE switch of the START command which is still working.
II. And the commands:
TAB is no longer autocomplete file names.Only in command prompt.
Starting a file by its extension - in disabled extensions mode the cmd will not get into account the HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\FileExts and //HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\FileExts\.ext\OpenWithList and will start directly only a "programs" - i.e. extensions described in %PATHEXT% variable.
Variable manipulation - replacements and substrings will not work with disabled extensions. Which means only with disabled extensions you can print the value of %=::% - undocumented variable that is defined only when the command prompt is not started with admin privileges.
ASSOC and FTYPE - not available under disabled extensions - related to the first point here.
CALL - no longer able to call labels but only other scripts.Argument modifiers are no longer supported (also in FOR command) - %~0, %~dp0, %~n0 will no longer working. Only plain access with %0,%1 ..
COLOR - no longer available. Though colors can be changed with other scripts.
IF - /I is not working. Three letter comparison operators (that can be used for integer comparisons) are not available - only ==. CMDEXTVERSION is not part of the options as well as DEFINED.
EXIT - Exit /b works ,but prints an error message as it tries to find the :EOF label. The printed error is not 'officially' documented.Only observable in batch files.
FOR - reduced to only basic for loops - the additional switches /F , /D , /R , /L are not available. Token modifiers will no longer working in a similar fashion of CALL arguments.
SHIFT - the /N switch is not working ,though is not 'officially' documented.
GOTO - :EOF label is not available anymore.
SET - switches /P and /A are no more working. Does not accept double quotes as part of the command (e.g. set "variable=value" will result in an error). Listing variables starting with a string is no longer possible (e.g. set path will cause an error). Only plain setting a variable value.
PUSHD - does no longer map temporary drives to UNC paths, and POPD does not delete such drives. Not officially documented.
PROMPT - does not support $+ and $M special codes
The HELP command deserves a note as it will not detect if the extensions are on or off and will print help messages as the extensions are available.
As COLOR , ASSOC , FTYPE (and IF DEFINED is not working) are the only commands turned off with disabled extensions are one of the best option to check if they are enabled (though COLOR will change the colour scheme).
But their output will be too big without the help message and help message is also not so small - which means even the redirection to null will slow down the check.
Eventually this also can be used to detect if the extensions are enabled:
call ::eof >nul 2>&1 && (
echo extensions are enabled
)||(
echo extensions are disabled
)
Or using assoc or ftype with an extension that will be available by default:
assoc .bat >nul 2>&1 && (
echo extensions are enabled
)||(
echo extensions are disabled
)
with ftype:
ftype batfile >nul 2>&1 && (
echo extensions are enabled
)||(
echo extensions are disabled
)
