How to send "Enter-key" through batch file to server connected via batch file

Question

Hi guys

With Gerhard's help, these below codes work perfectly for me

@echo off

set "range=10.151.12.11  10.151.13.11  10.151.27.11"
for %%i in (%range%) do (
   start "" cmdkey.exe /generic:"%%i" /user:"buffer" /pass:"123$"
   start "" mstsc.exe /admin /w:1600 /v:"%%i"

   timeout /t 1
)

In the below code, I made some changes to send the enter key, but it does not work

@echo off

set "range=10.151.12.11  10.151.13.11  10.151.27.11"
for %%i in (%range%) do

 (
   start "" cmdkey.exe /generic:"%%i" /user:"buffer" /pass:"123$"
   start "" mstsc.exe /admin /w:1600 /v:"%%i"

 WScript.CreateObject("WScript.Shell").SendKeys("{Enter}");

   timeout /t 1
)

Does anyone know how to send "Enter-key" in between these loops?

I want to send "Enter-key" after server is connected, then second server will connect

Aacini · Answer 1 · 2022-04-06T22:37:37.277

The simplest way to assemble an hybrid Batch file is combining it with JScript code, as in this example:

@if (@CodeSection == @Batch) @then


@echo off

set "range=10.151.12.11  10.151.13.11  10.151.27.11"
for %%i in (%range%) do (
   start "" cmdkey.exe /generic:"%%i" /user:"buffer" /pass:"123$"
   start "" mstsc.exe /admin /w:1600 /v:"%%i"

   Cscript //nologo //E:JScript "%~F0"

   timeout /t 1
)
goto :EOF


@end


WScript.CreateObject("WScript.Shell").SendKeys("{Enter}");

However, in order for this trick to work, the receiving window must have keyboard focus when the key is "pressed". Perhaps you need to also use AppActivate method to do that...

score -1 · Answer 2 · answered Apr 06 '22 at 18:54

-1

You are very close, but your problem is that WScript.CreateObject is not a batch command, but rather a VBScript command. In order to run that command in a batch script, you need to invoke the cscript interpreter for that line. Unfortunately, cscript only accepts files so you have to create a file with the WScript command in it.

set "range=10.151.12.11  10.151.13.11  10.151.27.11"
for %%i in (%range%) do (
    start "" cmdkey.exe /generic:"%%i" /user:"buffer" /pass:"123$"
    start "" mstsc.exe /admin /w:1600 /v:"%%i"
    
    >hit_enter.vbs echo WScript.CreateObject("WScript.Shell"^).SendKeys("{Enter}"^)
    cscript /nologo hit_enter.vbs
    del hit_enter.vbs
    timeout /t 1
)

answered Apr 06 '22 at 18:54

SomethingDark

13,229
5
50
55

Connecting to the server was successful, but sending the "enter-key" didn't work – faisal qureshi Apr 06 '22 at 20:13
How do you know it didn't work? What error message did you get? – SomethingDark Apr 06 '22 at 20:22
The connection to the server has an OK button; when we click on it, we will open the server fully so that we know your code won't be sent to the server and click on OK. – faisal qureshi Apr 06 '22 at 20:40
You're not going to be able to run local code on a remote host. – SomethingDark Apr 06 '22 at 22:57

How to send "Enter-key" through batch file to server connected via batch file

2 Answers2