How can I instantiate objects with similar/identical functionality but different properties?

Question

New to AS3, long time programmer. Essentially I am creating a myriad of objects, all of which will have the same functionality, although the properties will vary between each object, including the artwork. I believe they will all be movieclips as they will be interactive and I believe they will be moving.

I am wondering what the best way to create these objects are. I am assuming that I create an object class with the functionality and properties, I'm just unsure how to instantiate multiple copies with different properties, if that makes sense.

Sorry for my poor wording, I can help elaborate if necessary, and thank you for your help in advance! :)

Answer 1

Create a class.

package {
    import flash.display.MovieClip;

    public class MyMovieClip extends MovieClip {
    }
}

Add properties that may vary.

package {
    import flash.display.DisplayObject;
    import flash.display.MovieClip;

    public class MyMovieClip extends MovieClip {
        private var _borderColor : uint;
        private var _artWork : DisplayObject;
    }
}

Add possibilities to modify the properties. You may use constructor arguments or explicit getter/setter or you could declare your properties to be public.

package {
    import flash.display.DisplayObject;
    import flash.display.MovieClip;

    public class MyMovieClip extends MovieClip {
        private var _borderColor : uint;
        private var _artWork : DisplayObject;

        // using constructor parameters

        public function MyMovieClip(borderColor : uint, artWork : DisplayObject) {
            _borderColor = borderColor;
            _artWork = artWork;
        }

        // using setter/getter

        public function set borderColor(borderColor : uint) : void {
            _borderColor = borderColor;
        }

        public function get borderColor() : uint {
            return _borderColor;
        }

        public function set artWork(artWork : DisplayObject) : void {
            _artWork = artWork;
        }
        public function get artWork() : DisplayObject {
            return _artWork;
        }

    }
}

Create instances of the class and set them up using different values:

package  {
    import flash.display.Shape;
    import flash.display.Sprite;

    public class Main extends Sprite {
        public function Main() {
            var myMc1 : MyMovieClip = new MyMovieClip(0xFF0000, new Shape());
            var myMc2 : MyMovieClip = new MyMovieClip(0x0000FF, new Shape());
            var myMc3 : MyMovieClip = new MyMovieClip(0x00FF00, new Shape());

            myMc1.borderColor = 0xFF0000;
            myMc3.artWork = new Shape();
        }
    }
}

Answer 2

In AS3 the Object class is marked as dynamic in it's modifiers, subsequently you can dynamically add any properties you'd like to it. Also, similarly you could make your own class and mark it as dynamic and then add properties to them on the fly... in order to properly evaluate how to use those properties though might not be worth the complication, rather it's best to make different classes for different types of objects. If they share some base functionality then you can start by making a base class and extend it for each of your specific types of objects.

Read more about dynamic keyword here: http://help.adobe.com/en_US/FlashPlatform/reference/actionscript/3/statements.html?filter_flash=cs5&filter_flashplayer=10.2&filter_air=2.6#dynamic

However as I was saying above I think extension is probably a better method to achieve what you're trying to do... furthermore I'm a big advocate of using the Flex framework to make using AS3 easier, anyhow more on OOP with AS3 here: http://www.adobe.com/devnet/actionscript/articles/oop_as3.html

Let me know if this helps or you're looking for something else.