How to add multiple page number in a xsl tag

Question

I want to add a page number when there is more than one page in a xsl tag.

<Page Lien="../pages/Q_MLMQ_20220604_00000_N_002_003Y.pdf">02</Page>

In this example the page numbers are 02, and 003 (but i want to delete the 0).

If at the end there is a Y.pdf, i need the page number before the Y.pdf

<Page>2,3</Page>

If it's N.pdf, i do not need the page number before the N.pdf since it's only one page

<Page Lien="../pages/Q_MLMQ_20220604_00000_N_017_017N.pdf">17</Page>

<Page>17</Page>

Here's how i did it (but i only get page 2)

<xsl:if test="@Lien">

<xsl:element namespace="http://www.cedrom-sni.com/schema/newsv1.xsd" name="page">

<xsl:value-of select="format-number(..//Page, '#')"/>

</xsl:element>

</xsl:if>

I get

<Page>2</Page>

Thank you

Are you trying to extract the values between `_N_` and `Y.pdf`? If so, please state which version of XSLT your processor supports. — michael.hor257k, Jun 06 '22 at 19:58
First, thank you. I use . I yes, i need the values in _N_002_003Y. I need at the end 2,3. So if _N_002_002N. i would be 2 since article is only on one page. Thanks — Yvon Desjardins, Jun 06 '22 at 22:01
That is not what I asked. See here how to identify your processor: https://stackoverflow.com/a/25245033/3016153 — michael.hor257k, Jun 06 '22 at 22:18
Hi. Sorry i'm newbie. I only do the stylesheet with Notepad++ Here's what i have : — Yvon Desjardins, Jun 07 '22 at 12:02
Thank you so much for your kindness! it's MSXML3 (microsoft ) reagrds — Yvon Desjardins, Jun 07 '22 at 13:38

michael.hor257k · Answer 1 · 2022-06-07T14:23:59.457

Consider the following minimal example:

XML

<Pages>
    <Page Lien="../pages/Q_MLMQ_20220604_00000_N_002_003Y.pdf">02</Page>
    <Page Lien="../pages/Q_MLMQ_20220604_00000_N_017_017N.pdf">17</Page>
</Pages>

XSLT 1.0

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
<xsl:strip-space elements="*"/>

<!-- identity transform -->
<xsl:template match="@*|node()">
    <xsl:copy>
        <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
</xsl:template>

<xsl:template match="Page">
    <xsl:copy>
        <xsl:choose>
            <xsl:when test="contains(@Lien, 'Y.pdf')">
                <xsl:call-template name="tokenize">
                    <xsl:with-param name="text" select="substring-before(substring-after(@Lien, '_N_'), 'Y.pdf')"/>
                </xsl:call-template>
            </xsl:when>
            <xsl:when test="contains(@Lien, 'N.pdf')">
                <xsl:value-of select="number(substring-before(substring-after(@Lien, '_N_'), '_'))" />
            </xsl:when>
        </xsl:choose>
    </xsl:copy>
</xsl:template>

<xsl:template name="tokenize">
    <xsl:param name="text"/>
    <xsl:param name="delimiter" select="'_'"/>
    <xsl:value-of  select="number(substring-before(concat($text, $delimiter), $delimiter))" />
    <xsl:if test="contains($text, $delimiter)">
        <xsl:text>,</xsl:text>
        <!-- recursive call -->
        <xsl:call-template name="tokenize">
            <xsl:with-param name="text" select="substring-after($text, $delimiter)"/>
        </xsl:call-template>
    </xsl:if>
</xsl:template>

</xsl:stylesheet>

Result

<?xml version="1.0" encoding="UTF-8"?>
<Pages>
  <Page>2,3</Page>
  <Page>17</Page>
</Pages>

How to add multiple page number in a xsl tag

1 Answers1