Way to convert unsigned 64-bit integer into floating point?

Question

I need an x86 sequence to convert a 64-bit unsigned integer into a floating point. This would be simple enough with a signed integer, but there doesn't seem to be an instruction that can do so with one that is unsigned. I believe you could normally use VCVTUSI2SD, but this is not accessible by my assembler.

So in terms of assembly, it would accomplish this:

unsigned long long x = ... ;
double y = (double)x;

Another similar question was posted here but involves 32-bit register manipulation. This requires the conversion of 64-bit values instead, which adds some complexity to the math.

Answer 1

I assume Intel x86_64 here. You would typically use cvtsi2sd in these cases with treatment of sign

https://www.felixcloutier.com/x86/cvtsi2sd

//
// prototype: double convert(uint64_t value)
//
convert(unsigned long):        
        testq   %rdi, %rdi
        js      .Negative
        pxor    %xmm0, %xmm0
        cvtsi2sdq       %rdi, %xmm0
        ret
.Negative:
        movq    %rdi, %rax
        andl    $1, %edi
        pxor    %xmm0, %xmm0
        shrq    %rax
        orq     %rdi, %rax
        cvtsi2sdq       %rax, %xmm0
        addsd   %xmm0, %xmm0
        ret

Basically because cvtsi2sdq takes a signed integer, you obviously have to treat the case where the uint64_t would be recognized as a negative.

Basically what this code is doing is something like this:

double signed_convert( int64_t value ); // trivial

double convert( uint64_t value ) {
   if ( value>>63 == 0 ) return signed_convert( value );
   double half = signed_convert( (value>>1) | (value&1) );
   return 2*half;
}