Build failing with androidx.navigation.safeargs.kotlin

Question

I am unable to add navigation components to my project. I am constantly getting following error:

An exception occurred applying plugin request [id: 'androidx.navigation.safeargs.kotlin'] Failed to apply plugin 'androidx.navigation.safeargs.kotlin'. safeargs plugin must be used with android plugin

My build gradle looks like this:

    id 'androidx.navigation.safeargs.kotlin'
    id 'com.android.application'
    id 'org.jetbrains.kotlin.android'
    id 'kotlin-kapt'
    id 'kotlin-android'
    id 'kotlin-android-extensions'
}

android {
    compileSdk 33

    defaultConfig {
        applicationId "com.mushroomgathererv1"
        minSdk 21
        targetSdk 32
        versionCode 1
        versionName "1.0"

        testInstrumentationRunner "androidx.test.runner.AndroidJUnitRunner"
    }

    buildTypes {
        release {
            minifyEnabled false
            proguardFiles getDefaultProguardFile('proguard-android-optimize.txt'), 'proguard-rules.pro'
        }
    }
    compileOptions {
        sourceCompatibility JavaVersion.VERSION_1_8
        targetCompatibility JavaVersion.VERSION_1_8
    }
    kotlinOptions {
        jvmTarget = '1.8'
    }

    buildFeatures {
        viewBinding true
    }
}

dependencies {

    implementation 'androidx.core:core-ktx:1.9.0'
    implementation 'androidx.appcompat:appcompat:1.5.1'
    implementation 'com.google.android.material:material:1.6.1'
    implementation 'androidx.constraintlayout:constraintlayout:2.1.4'
    testImplementation 'junit:junit:4.13.2'
    androidTestImplementation 'androidx.test.ext:junit:1.1.3'
    androidTestImplementation 'androidx.test.espresso:espresso-core:3.4.0'
    //additional dependency
    implementation 'com.google.android.gms:play-services-location:20.0.0'

    // Navigation Component
    implementation 'androidx.navigation:navigation-fragment-ktx:2.5.2'
    implementation 'androidx.navigation:navigation-ui-ktx:2.5.2'

    // Room components
    implementation "androidx.room:room-runtime:2.4.3"
    kapt "androidx.room:room-compiler:2.4.3"
    implementation "androidx.room:room-ktx:2.4.3"
    androidTestImplementation "androidx.room:room-testing:2.4.3"

    // Lifecycle components
    implementation "androidx.lifecycle:lifecycle-extensions:2.2.0"
    implementation "androidx.lifecycle:lifecycle-common-java8:2.5.1"
    implementation "androidx.lifecycle:lifecycle-viewmodel-ktx:2.5.1"

    // Kotlin components
    implementation "org.jetbrains.kotlin:kotlin-stdlib-jdk7:1.6.0"
    api "org.jetbrains.kotlinx:kotlinx-coroutines-core:1.6.1"
    api "org.jetbrains.kotlinx:kotlinx-coroutines-android:1.6.1"

}

And the other one:


plugins {
    id 'com.android.application' version '7.2.2' apply false
    id 'com.android.library' version '7.2.2' apply false
    id 'org.jetbrains.kotlin.android' version '1.6.10' apply false
    id 'androidx.navigation.safeargs' version '2.5.2' apply false
}

task clean(type: Delete) {
    delete rootProject.buildDir
}

Is there anything that I am missing here?

Does this answer your question? [Plugin with id 'androidx.navigation.safeargs' not found](https://stackoverflow.com/questions/53921194/plugin-with-id-androidx-navigation-safeargs-not-found) — Code-Apprentice, Jun 25 '23 at 18:58

score 0 · Answer 1 · answered Aug 23 '23 at 10:18

I solved this for me by moving the safeargs plugin below both the android and kotlin plugins - my app/build.gradle.kts:

plugins {
    id("com.android.application")
    id("org.jetbrains.kotlin.android")
    id("androidx.navigation.safeargs.kotlin")
    // ...
}

Build failing with androidx.navigation.safeargs.kotlin

1 Answers1