Replace multiple strings with multiple values in Julia

Question

In Python pandas you can pass a dictionary to df.replace in order to replace every matching key with its corresponding value. I use this feature a lot to replace word abbreviations in Spanish that mess up sentence tokenizers.

Is there something similar in Julia? Or even better, so that I (and future users) may learn from the experience, any ideas in how to implement such a function in Julia's beautiful and performant syntax?

Thank you!

Edit: Adding an example as requested

Input:

julia> DataFrames.DataFrame(Dict("A" => ["This is an ex.", "This is a samp.", "This is a samp. of an ex."]))
3×1 DataFrame
 Row │ A                  
     │ String             
─────┼────────────────────
   1 │ This is an ex.
   2 │ This is a samp.
   3 │ This is a samp. of an ex.

Desired output:

3×1 DataFrame
 Row │ A                  
     │ String             
─────┼────────────────────
   1 │ This is an example
   2 │ This is a sample
   3 │ This is a sample of an example

Bogumił Kamiński · Accepted Answer · 2022-10-16T07:17:57.817

In Julia the function for this is also replace. It takes a collection and replaces elements in it. The simplest form is:

julia> x = ["a", "ab", "ac", "b", "bc", "bd"]
6-element Vector{String}:
 "a"
 "ab"
 "ac"
 "b"
 "bc"
 "bd"

julia> replace(x, "a" => "aa", "b" => "bb")
6-element Vector{String}:
 "aa"
 "ab"
 "ac"
 "bb"
 "bc"
 "bd"

If you have more complex replace pattern you can pass a function that does the replacement:

julia> replace(x) do s
           length(s) == 1 ? s^2 : s
       end
6-element Vector{String}:
 "aa"
 "ab"
 "ac"
 "bb"
 "bc"
 "bd"

There is also replace! that does the same in-place.

Is this what you wanted?

EDIT

Replacement of substrings in a vector of strings:

julia> df = DataFrame("A" => ["This is an ex.", "This is a samp.", "This is a samp. of an ex."])
3×1 DataFrame
 Row │ A
     │ String
─────┼───────────────────────────
   1 │ This is an ex.
   2 │ This is a samp.
   3 │ This is a samp. of an ex.

julia> df.A .= replace.(df.A, "ex." => "example", "samp." => "sample")
3-element Vector{String}:
 "This is an example"
 "This is a sample"
 "This is a sample of an example"

Note two things:

you do not need to pass Dict to DataFrame constructor. It is enough to just pass pairs.
In assignment I used .= not =, which perfoms an in-place replacement of updated values in the already existing vector (I show it for a comparison to what @Sundar R proposed in a comment which is an alternative that allocates a new vector; the difference probably does not matter much in your case but I just wanted to show you both syntaxes).

`replace!` is only for arrays and other mutable collections. Since Strings are immutable, only `replace` exists for Strings. — Sundar R, Oct 15 '22 at 20:55
Also, since the title mentions multiple strings, and the question mentions `pandas`, I believe they want to do this replace over a DataFrame column, like `df.x = replace.(df.x, ...)`. — Sundar R, Oct 15 '22 at 20:56
Thank you, this is brilliant. And the implementation is even better than Python's, in that it support regex out of the box, and counts for max replacements, which is a boon. @Sundar R, you're right in that I did want to replace multiple rows, and your broadcasting syntax did the final trick. I'm accepting the answer given that it's thorough enough to get *just there*, but I guess it'd be great if it could be edited to reflect Sundar's input too. Thank you both! — Dijkie85, Oct 15 '22 at 21:32
In these cases I usually prefer to have a _map_ that describes my replacements in terms of a dictionary and then just use the old valies as the keys and the new, replaced values as the dict value. — Antonello, Oct 15 '22 at 21:38
I can edit the answer, but can you give in your question an example input and example expected output so that I know exactly what you want? Thank you! — Bogumił Kamiński, Oct 15 '22 at 21:43

Replace multiple strings with multiple values in Julia

1 Answers1

EDIT