How can I merge two tables in Google Sheets by ID like in SQL?

Question

Suppose I have two tables, table1 and table2, like these:

table1

ID VALUE
0  2
1  8
4  3

table2

ID VALUE
1  9
3  5
0  1

How can I merge table1 and table2, such that the resulting table contains ID,VALUE1,VALUE2? Note: VALUE is different between table1 and table2. Also, the tables are unsorted and have different length, so there may be an ID in table1 that doesn't exist in table2 and vice-versa.

Resulting table

ID VALUE1 VALUE2
0  2      1
1  8      9

I have managed to select only the rows from table1 using this formula:

=INDEX(table1!$A$2:$B$4;MATCH(table2!$A2;table2!$A$2:$A$4;0))

In SQL, this could be easily done with:

SELECT table1.ID, table1.VALUE AS VALUE1, table2.VALUE AS VALUE2
FROM table1 
INNER JOIN table2 ON table1.ID = table2.ID

Does this answer your question? [Google spreadsheet "=QUERY" join() equivalent function?](https://stackoverflow.com/questions/14796620/google-spreadsheet-query-join-equivalent-function) — Anuj Kumar, Dec 20 '22 at 13:48

score 1 · Answer 1 · answered Dec 20 '22 at 18:36

1

Here's an approach you can use in sheets.

Table1: A:B

Table2: D:E

Output cell formula G2:

=BYROW(UNIQUE(SORT(FILTER(A2:A,MATCH(A2:A,D2:D,0)*(A2:A<>"")),1,1)),LAMBDA(ax,{ax,TRANSPOSE(FILTER({B:B;E:E},{A:A;D:D}=ax,{A:A;D:D}<>""))}))

-

answered Dec 20 '22 at 18:36

rockinfreakshow

15,077
3
12
19

score 1 · Accepted Answer · answered Dec 20 '22 at 18:55

I found a way to do it with QUERY, though copying the data from table1 to another sheet, because I needed to keep table1 and table2 intact. Here's how to do it:

Create another sheet and paste the code below on the first cell:

=QUERY(table1!A:B;"SELECT A,B label B 'VALUE1'")

Then name column C1 as VALUE2 and paste the code below on cell C2:

=ARRAYFORMULA(VLOOKUP(A2:A;table2!A:B;2;FALSE))

How can I merge two tables in Google Sheets by ID like in SQL?

2 Answers2