awk how to set varA from fileA and varB from fileB

Question

What my logic is:

1. To divide (column 3 by column 2) and show the result (these calculation is read from fileB).
2. To show the the actual values (untouched, read from FileA)
3. If the result is zero (zero division error), write it to zero_file, if result is between 1 and 6, write it to between_file, if is more than 8, write it to great_file, if it's neither of those, write it to neither_file.

fileA:

col1 col2 col3 col4
1    1K   2K   name1
2    0    3K   name2
3    1K   20M  name3
4    2K   14K  name4

fileB:

col1 col2 col3     col4
1    1000 2000     name1
2    0    3000     name2
3    1000 20000000 name3
4    2000 14000    name4

Why two files?

These two above files are generated somewhere else and the values are not fixed (so, let us skip how them are made).

fileB is calculated from fileA and all K and Ms are converted to bytes.

Expected output

I am trying to fileB --> col3 divide by col2 (if it's zero or greater than 8 or between 1 and 4 (different conditions)), then show the values from fileA --> it is calculated from col3 by col2:

The name1's rate is 2 (it is calculated from 2K by 1K).
The name2's rate is 0 (it is calculated from 3K by 0).
The name3's rate is 20000 (it is calculated from 20M by 1K).
The name4's rate is 7 (it is calculated from 14K by 2K).

My attempts

This is my another attempt (with double quotes):

awk "
(NR == FNR) {
   rate = (!\$2 ? 0 : \$3/\$2)
   rx = (\$2)
   tx = (\$3)
   file_name = \"$PWD/file\"
   next
}
rate >= 1 && rate <= 4 {file_name=\"$PWD/file\"}
rate >= 8 {file_name=\"$PWD/file\"}
!rate {file_name=\"$PWD/file\"}
{
   first = (\$2)
   second = (\$3)
}
END {
   print \"ratio for\", \$NF, \"is\", rate, \"(result original receive:\", first \", original transfer:\", second \")\" > file_name
}" col3 col2

This is my another attempt (with single quotes and no variables):

awk '
(NR == FNR) {
   rate = (!$2 ? 0 : $3/$2)
   rx = ($2)
   tx = ($3)
   file_name = "/path/file"
   next
}
rate >= 1 && rate <= 4 {file_name="/path/file"}
rate >= 8 {file_name="/path/file"}
!rate {file_name="/path/file"}
{
   first = ($2)
   second = ($3)
}
END {
   print "ratio for", $NF, "is", rate, "(result original receive:", first ", original transfer:", second ")" > file_name
}' col3 col2

My issue with my attempt

ratio for name4 is 7 (result original receive: 2K, original transfer: 14K)

It only shows the last column, but not all columns.

This was my latest but unsuccessful attempt.

Answer 1

As discussed in comments above, this awk solution produces output using fileA only:

awk -v dir='/tmp' '
BEGIN {
   dir = (dir ? dir : ".") "/"
}
function tobytes(v) {
   return v * (v ~ /M$/ ? 1000000 : (v ~ /K$/ ? 1000 : 1))
}
NR == 1 {
   next
}
{
   denom = tobytes($2)
   numer = tobytes($3)
   r = (denom ? numer / denom : 0)
   fn = "neither_file"
}
r >= 8 {
   fn ="great_file"
}
r >= 1 && r<= 6 {
   fn = "between_file"
}
!r {
   fn = "zero_file"
}
{
   print "The", $NF "\047s rate is", r > (dir fn)
}' fileA

Output:

awk 'FNR == 1 {print "::", FILENAME, "::"} 1' /tmp/*_file

:: between_file ::
The name1's rate is 2
:: great_file ::
The name3's rate is 20000
:: neither_file ::
The name4's rate is 7
:: zero_file ::
The name2's rate is 0

Change the print to:

printf "The %s\047s rate is %s (it is calculated from %s by %s).\n", $NF, r, $3, $2

to see the $2 and $3 values in the output.

Answer 2

@Saeed : to conveniently convert those units to bytes, you can try this ::

-- since all the units are just powers of 1,024, which is 32 ^ 2, one can craft a lookup reference string that can translate all of them to bytes, accepting

— either the 1st letter only, or the 1st 2 letters and ignoring the rest, 
- in any casing, 
- of either sign, and
- any extra spaces in between  

---

# gawk profile, created Sun Jun  4 16:34:59 2023

# BEGIN rule(s)

BEGIN {
 1      CONVFMT = "%.16g"
 1      FS = RS
 1      ORS = "\n\n"
 1      OFS = "\f\t"
}

# Rule(s)

 6  ($++NF = any2bytes($1)) ^ _ { # 6
 6      print
}

  # Functions, listed alphabetically

 6  function any2bytes(__,_) {
 6      return \
        int(sub(/[^.[:alnum:]+-]+/, _ = "",
              __)^_ > match(__ = toupper(__), /[E-KMP-Z](B|$)/) \
        ? +__ \
        : __ * ((_ += ++_) * _^_^_) ^ index("_KBMBGBTBPBEBZBYBRBQB",
                                     substr(__, RSTART, RLENGTH ) ) )
    }

---

8362322323
                 8362322323

1003569bytes
                    1003569

173.77KB
                     177940

 +23.9517 mb
                   25115177

444.19GB
               476945380802

 -12.73 T
            -13996783021588

---

The Bs were kept in the code above for clarity. You can streamline it further by discarding all the Bs and changing the exponent's base from 32 to 1,024,

or simply, 4 ^ 5 ::

function any2bytes(__, _) {

    return int(sub("[^[:alnum:]+--]+",_ = "", __)^_++ \
           > match(__ = toupper(__), "[E-KMP-Z](B|$)") \
        ? __ \
        : __ * ((_+= ++_)^++_)^index("KMGTPEZYRQ", 
                               substr(__,  RSTART, !!_)))
}