French partitive ‘de’

Question

What is the best way in the GF RGL to represent the thing that French grammar books usually call the “partitive article” (du, de la, des)?

Examples:

Je voudrais de l'eau
I would like some water
Il y a du vin ici
There is some wine here

The options I see are:

As a determiner? If so, which one? I couldn’t find a ready-made determiner in the RGL that serializes into this. The likely candidates someSg_Det and somePl_Det linearize into something else.
Or as a preposition (de) followed by the definite article (le, la, les)? Because that’s what this so-called “partitive article” can be quite obviously and losslessly decomposed into.

I’m inclined to go for Option 2, but I prefer to ask in case there is a ready-made determiner somewhere that I’ve missed.

Also, I suspect this question must have been asked before by people making use of the French RGL because this partitive thingy is quite common in French.

score 2 · Accepted Answer · answered Aug 18 '23 at 12:43

I haven't personally been involved in the design of the French resource grammar, it's one of the oldest in the RGL, and I just haven't worked with French in any of my projects, so I actually don't know much about it. But this is what I found out by quick experimentation:

resource Test = open SyntaxFre, LexiconFre, IrregFre, ParadigmsFre in {
  oper
    -- create some NPs with different determiners
    wine : NP = mkNP wine_N ;            -- using MassNP
    aWine : NP = mkNP aSg_Det wine_N ;
    theWine : NP = mkNP the_Det wine_N ;
    someWine : NP = mkNP someSg_Det wine_N ;

    -- Use vouloir_V2 that takes a direct object
    vouloirDefault : NP -> S ;
    vouloirDefault np = mkS (mkCl i_NP IrregFre.vouloir_V2 np) ;

    -- Use a version of vouloir that always introduces object with de
    vouloirDe : NP -> S ;
    vouloirDe np = mkS (mkCl i_NP vouloir_always_de_V2 np) ;

    vouloir_always_de_V2 : V2 = 
      ParadigmsFre.mkV2 IrregFre.vouloir_V ParadigmsFre.genitive ;
}

And running this in the GF shell, we find the following:

> cc -one vouloirDefault wine
je veux du vin

> cc -one vouloirDefault aWine
je veux un vin

> cc -one vouloirDefault theWine
je veux le vin

> cc -one vouloirDefault someWine
je veux quelque vin

The overload instance mkNP : N -> NP comes from the MassNP construction, so that's one way to get an NP with "du/de la N". We see that just applying the default vouloir_V2 to the 4 different NPs, then du comes from the NP, not from the verb.

Then another way is to specify that the V2 should introduce every object with de, like we do in vouloir_always_de_V2. This gives the following results:


> cc -one vouloirDe wine
je veux de vin

> cc -one vouloirDe aWine
je veux d'un vin

> cc -one vouloirDe theWine
je veux du vin

> cc -one vouloirDe someWine
je veux de quelque vin

OK, I get it: every NP has a partitive form of itself inside itself as one of its forms, and you can bring it out with the preposition `ParadigmsFre.genitive`. That’s not ideal because it makes it difficult to modify the NP with another preposition, like “avec du vin” ‘with some wine’. But, OK. — Michal Měchura, Aug 18 '23 at 15:12
This works fine for me: `avecDuVin : Adv = SyntaxFre.mkAdv with_Prep (mkNP wine_N) ;` And it linearises as expected, "avec du vin". — inariksit, Aug 19 '23 at 07:23
So what `MassNP` does is that it puts the "du vin" or "de la bière" form in the accusative of the inflection table, and then any preposition or V2 that takes the Acc form, will access the "de la/du" form instead. — inariksit, Aug 19 '23 at 07:43
I guess I was wrong when I claimed you can't easily build "avec du vin" with the RGL. You can. Thank you! — Michal Měchura, Aug 19 '23 at 19:16

French partitive ‘de’

1 Answers1