Perl: Format US phone number based on input

Question

This didn't answer my question.

Possible inputs (may have whitespace):

full number: (XXX) XXX-XXXX
full number: XXX/XXX-XXXX
full number: XXXXXXXXXX
no area code: XXX-XXXX
no area code: XXXXXXX
extension only: XXXX

So if you regex it for digits only s/[^\d]//g, you'll hopefully get 1 of 3 options:

XXXXXXXXXX
XXXXXXX
XXXX

Which I would like to format as so:

XXX/XXX-XXXX
XXX-XXXX
XXXX

Is the best way to do this to do if statements based on the length? Or is there a more one-liner approach?

You may want to take a look at [this question and answer][1] [1]: http://stackoverflow.com/questions/123559/a-comprehensive-regex-for-phone-number-validation — SparkeyG, Oct 14 '11 at 16:55
@SparkeyG: That is a link to the very first word/link in my post-??? — vol7ron, Oct 14 '11 at 20:38

score 5 · Answer 1 · answered Oct 14 '11 at 16:22

5

I'd just use if statements, because they're a lot clearer and easier to extend:

if (length($number) == 4) {
  # extension
} elsif (length($number) == 7) {
  # no area code
} elsif (length($number) == 10) {
  # full number
} else {
  die "unsupported number";
}

If you're using Perl 5.10 or higher, you can use the switch:

use feature "switch";

given (length($number) {
  when (4) { # extension }
  when (7) { # no area code }
  when (10) { # full number }
  default { die "unsupported number"; }
}

Either of these give the advantage of being easily modified to, for example, take a number that starts with 1 (i.e. 1-555-123-4567).

answered Oct 14 '11 at 16:22

CanSpice

34,814
10
72
86

This approach is more flexible than my approach. – mob Oct 14 '11 at 16:41
This is the way I'm doing it now, I was hoping I could use positive look behinds and figure out the matches that way. You guys have been pretty knowledgeable about Perl, I could use your guys help with my answer. – vol7ron Oct 14 '11 at 19:27
@vol7ron: Sometimes you just need to forget about regexes. They're not the solution for everything. :-) – CanSpice Oct 14 '11 at 19:35
Forgot to say +1 for your answer. I think I'm going to stick with what I have (in the answer I came up with), since it should use fewer lines and I like how the delimiters are used. – vol7ron Oct 14 '11 at 21:01

score 1 · Answer 2 · answered Oct 14 '11 at 16:32

1

You can use a sequence of substitutions.

s#[^\d]##g;
s#(\d{3})(\d{4})$#$1-$2#;
s#(\d{3})(\d{3})-#$1/$2-#;

The second substitution will fail (i.e., have no effect) if the input has less than 7 digits, and the third substitution will fail if the input has less than 10 digits.

answered Oct 14 '11 at 16:32

mob

117,087
18
149
283

+1, sequence of substitutions aren't bad, especially on strings so small. – vol7ron Oct 14 '11 at 21:08

score 1 · Answer 3 · answered Oct 14 '11 at 18:59

1

This should do it:

perl -pne's;(?:\(?(\d{3})[\)/]?\s*)?(?:(\d{3})-?)?(\d{4});$1/$2-$3;||die("bad #: $_") and s;^/-?;;'

Example:

$ echo "(123)456-7890
(123) 456-7890
123/456-7890
1234567890
456-7890
7890
foobar
" |perl -pne's;(?:\(?(\d{3})[\)/]?\s*)?(?:(\d{3})-?)?(\d{4});$1/$2-$3;||die("bad #: $_") and s;^/-?;;'
123/456-7890
123/456-7890
123/456-7890
123/456-7890
456-7890
7890
bad number: foobar at -e line 1, <> line 7.

answered Oct 14 '11 at 18:59

MisterEd

1,725
1
14
15

certainly like the one-liners, don't you :) – vol7ron Oct 14 '11 at 19:29

score 1 · Accepted Answer · edited Jun 20 '20 at 09:12

CodePad

sub phoneFormat{
    my @sigils  = ('+','/','-');            # joiners
    $_ = reverse(shift);                    # input; reversed for matches
    @_ = grep{defined} unpack "A4A3A3A1",$_;    # match, starting with extension; and remove unmatched
    $_ = join('', map {$_ . pop @sigils } @_ ); # add in the delimiters
    ($_ = reverse) =~ s/^[^\d]+//;          # reverse back and remove leading non-digits
    $_;
}

print phoneFormat('012')         , "\n";    # (blank)
print phoneFormat('0123')        , "\n";    # 0123
print phoneFormat('0123456')     , "\n";    # 012-3456
print phoneFormat('0123456789')  , "\n";    # 012/345-6789
print phoneFormat('01234567899') , "\n";    # 0+123/456-7899
print phoneFormat('012345678999') , "\n";   # 1+234/567-8999

score 0 · Answer 5 · answered Oct 14 '11 at 22:02

for(<DATA>){
  /^.*?: \s* \(? (\d{3})?? [)\/]? \s* (\d{3})? \s* [-]? \s* (\d{4}) \s* $/x;
  print "$&\t";
  print "$1 / " if $1;
  print "$2 - " if $2;
  print "$3\n"  if $3;      
}


__DATA__
* full number: (123) 456-7890
* full number: 123/456-7890
* full number: 1234567890
* no area code: 456-7890
* no area code: 4567890
* extension only: 7890

OUTPUT

* full number: (123) 456-7890
123 / 456 - 7890
* full number: 123/456-7890
123 / 456 - 7890
* full number: 1234567890
123 / 456 - 7890
* no area code: 456-7890
456 - 7890
* no area code: 4567890
456 - 7890
* extension only: 7890
7890

You could also use named captures like (?<area>\d{3}) to increase readability!

Perl: Format US phone number based on input

5 Answers5

CodePad