Decrementing for loop in coffeescript

Question

I know how to do a incrementing for loop in coffeescript such as:

Coffeescript:

for some in something

Generated Javascript:

for (_i = 0, _len = something.length; _i < _len; _i++)

How do I create a decrementing for loop similar to this in Coffeescript?

for (var i = something.length-1; i >= 0; i--)

score 51 · Accepted Answer · edited Oct 15 '14 at 20:44

51

EDIT: As of CoffeeScript 1.5 by -1 syntax is supported.

First, you should familiarize yourself with the by keyword, which lets you specify a step. Second, you have to understand that the CoffeeScript compiler takes a very naïve approach to loop endpoints (see issue 1187, which Blender linked to), which means that

for some in something by -1 # don't do this!!!

will result in an infinite loop—it starts at index 0, increments the index by -1, and then waits until the index hits something.length. Sigh.

So you need to use the range loop syntax instead, which lets you specify those endpoints yourself—but also means you have to grab the loop items yourself:

for i in [something.length - 1..0] by -1
  some = something[i]

Obviously that's pretty messy. So you should strongly consider iterating over something.reverse() instead. Just remember that reverse() modifies the array that you call it on! If you want to preserve an array but iterate over it backwards, you should copy it:

for some in something.slice(0).reverse()

edited Oct 15 '14 at 20:44

Soviut

88,194
49
192
260

answered Oct 27 '11 at 19:06

Trevor Burnham

76,828
33
160
196

1

I think you don't even need the `-1`. `for i in [sth.length-1..0]` works fine – Ricardo Tomasi Oct 29 '11 at 03:31
4

@RicardoTomasi You're correct that it will work without the `by -1`, but it's less efficient—look at the compiled output for both. From the compiler's perspective, `something.length` is potentially negative, so the step is potentially either `1` or `-1`. – Trevor Burnham Oct 29 '11 at 17:08
@RicardoTomasi You need the `by -1 ` if `sth` is an empty array. Otherwise the loop would run two times more than expected (zero times). Once for `-1` and once for `0`. – Robert Sep 21 '12 at 22:38
1

@Robert good catch. `for i in [sth.length-1...-1]` "fixes" that :D – Ricardo Tomasi Sep 23 '12 at 18:50
1

Note that `array[..]` is shorthand for `array.slice(0)`. – davidchambers Feb 10 '13 at 05:33
1

@davidchambers True, as of CoffeeScript 1.3.1. – Trevor Burnham Feb 10 '13 at 15:35

score 38 · Answer 2 · answered Apr 01 '13 at 17:07

38

As of coffee-script 1.5.0 this is supported:

for item in list by -1
  console.log item

This will translate into

var item, _i;
for (_i = list.length - 1; _i >= 0; _i += -1) {
  item = list[_i];
  console.log(item);
}

answered Apr 01 '13 at 17:07

Evan Moran

3,825
34
20

2

You can also use the `element, index` syntax with this like: `console.log "#{item.toString()} at index #{index}" for item, index in list by -1` – glampr May 24 '13 at 13:15

Ricardo Tomasi · Answer 3 · 2011-10-29T03:40:33.333

2

A different take just for the record:

i = something.length
while item = something[--i]
  #use item

(will break on falsy values)

edited Oct 29 '11 at 03:40

answered Oct 29 '11 at 03:34

Ricardo Tomasi

34,573
2
55
66

this one doesn't break when used over empty arrays – david Jan 20 '16 at 15:51

score 1 · Answer 4 · edited May 11 '13 at 01:40

1

There doesn't seem to be an elegant way to loop in reverse.

I checked the GitHub ticket regarding this, but it has been closed: https://github.com/jashkenas/coffee-script/issues/1187

The syntax used to be:

for some in something by -1

But it has been removed in recent versions. EDIT: it works now (for 1.6.2 @time of edit)

edited May 11 '13 at 01:40

Angelos Pikoulas

1,002
1
14
21

answered Oct 27 '11 at 19:01

Blender

289,723
53
439
496

score 0 · Answer 5 · answered Feb 03 '15 at 21:35

For a decrementing, index-based for loops, you can use:

for i in [0...something.length].reverse()

This removes the messiness @TrevorBurnham mentioned is an issue with specifying endpoints yourself.

When something.length is 0, this is equivalent to

for i in []

Jacob Oscarson · Answer 6 · 2011-10-28T08:51:30.573

0

Idiomatic way (from docs) along the lines of:

lst = ['a', 'b', 'c']
for n in (num for num in [lst.length-1..0])
  alert lst[n]

(Edited after @Trevor's note)

Edit:

Although, if performance is critical, this equivalent but maybe less aesthetic snippet will generate less resulting javascript:

lst = [1,2,3]
i = lst.length
alert lst[i] while i--

edited Oct 28 '11 at 08:51

answered Oct 27 '11 at 19:01

Jacob Oscarson

6,363
1
36
46

Umm, this only works if `lst` is `[1,2,3]`. If you try, say, `lst = ['a','b','c']`, the output will still be `3`, `2`, `1`. – Trevor Burnham Oct 27 '11 at 19:08

Decrementing for loop in coffeescript

6 Answers6

Linked

Related