Printing a character to standard output in Assembly x86

Question

I'm a little confused about how to print a character to the screen using Assembly. The architecture is x86 (linux). Is it possible to call one of the C functions or is there a simpler way? The character I want to output is stored in a register.

Thanks!

Answer 1

In the interest of completeness, here is how to do it without C.

Using DOS interrupts

AH = 02h -WRITE CHARACTER TO STANDARD OUTPUT

Writes character in DL. (I tested this with the DOS emulator emu2)

mov dl, 21h ; char '!'
mov ah, 02h ; char output service
int 21h     ; call DOS services

x86-32 Linux write syscall

write requires the address of your string. For a single character you can push your character on the stack.

push    '!'         ; push dword
mov     eax, 4      ; write call number, __NR_write from unistd_32.h
mov     ebx, 1      ; write to stdout (fd=1)
mov     ecx, esp    ; use char on stack
mov     edx, 1      ; write 1 char
int     0x80        ; call into the kernel
add     esp, 4      ; restore sp 

Info on register order

x86-64 Linux write syscall

Similar to above, but the call number is now 1, syscall instead of int 0x80, and the calling convention registers are different.

push    '!'         ; push qword 0x21
mov     rax, 1      ; write call number, __NR_write from unistd_64.h
mov     edi, 1      ; write to stdout (int fd=1)
mov     rsi, rsp    ; use char on stack
mov     rdx, 1      ; size_t len = 1 char to write.
syscall            ; call the kernel, it looks at registers to decide what to do
add     rsp, 8      ; restore stack pointer

mov edx, 1 does exactly the same thing as mov rdx, 1, but NASM will optimize it for you. This code uses operand-sizes that match the C types, not optimizing mov of small non-negative 64-bit integers.

Answer 2

Sure, you can use any normal C function. Here's a NASM example that uses printf to print some output:

;
; assemble and link with:
; nasm -f elf test.asm && gcc -m32 -o test test.o
;
section .text

extern printf   ; If you need other functions, list them in a similar way

global main

main:

    mov eax, 0x21  ; The '!' character
    push eax
    push message
    call printf
    add esp, 8     ; Restore stack - 4 bytes for eax, and 4 bytes for 'message'
    ret

message db 'The character is: %c', 10, 0

If you only want to print a single character, you could use putchar:

push eax
call putchar

---

If you want to print out a number, you could do it like this:

mov ebx, 8
push ebx
push message
call printf
...    
message db 'The number is: %d', 10, 0

Answer 3

Calling putchar(3) is the simplest way. Just move the char's value into the rdi register (for x86-64, or edi for x86), and call putchar.

E.g. (for x86-64):

asm("movl $120, %rdi\n\t"
    "call putchar\n\t");

will print an x to stdout.