Perl, comparing scalar to array (with regex?)

Question

I'll be brief so I don't waste your time;

Simple problem, i have an array of say, hundreds of dogs

my @dogs = qw(Shepard Lab Dalmation Husky Chow Pitbull ...)

and i want to compare it to a single dog

my $doggy = "Shepard";

pretty stupid i know, but how would i do that?

# Regex match against array?
# (This doesnt even work but its how i would think of doing it)
if ($doggy =~ /@dogs/) {
print $doggy;
}

Thanks for any answers in advance, I appreciate you guys helping me with what is probably a really stupid question. Thank you

Answer 1

I would do it like this :

my %hDogs = map { $_ => 1 } @dogs;

if(exists($hDogs{$doggy})) { ... }

Answer 2

You can just use grep:

my @dogs = qw(Shepard Lab Dalmation Husky Chow Pitbull);
my @wanted_dogs = grep {/^Shepard$/} @dogs;
print "@wanted_dogs\n";

Result:

Shepard

The regex can be changed as wanted, and if you're only interested in the first matching dog, you'll find that in $wanted_dogs[0].

Answer 3

Smart match operator:

use warnings;
use strict;

my @dogs = qw(Shepard Lab Dalmation Husky Chow Pitbull);
my $doggy = "Shepard";
if ($doggy ~~ @dogs) {
    print $doggy;
}

Answer 4

Assuming you don't really want a regular expression match and just want to see if there is an exact match somewhere in the list, then you have a number of options.

Smart match is the relatively new, but simplest and possibly fastest approach.

The classic methods are grep and List::Util::first. You can adjust the latter two to use a regex instead of eq if you do want to (for example) match "Shepard" when $dog is "Shep".

use strict;
use warnings;
use v5.10;

my @dogs = qw(Shepard Lab Dalmation Husky Chow Pitbull);
my $dog = "Shepard";
my $cat = "Ocicat";

say "Smart match";
say $dog ~~ @dogs;
say $cat ~~ @dogs;

say "Grep";
say grep { $_ eq $dog } @dogs;
say grep { $_ eq $cat } @dogs;

say "List::Util";
use List::Util qw/first/;
say first { $_ eq $dog } @dogs;
say first { $_ eq $cat } @dogs;

Answer 5

There are techniques using the newer smart-match operator, but I prefer the old classic:

my $dogs_re = join '|' => map quotemeta, @dogs;

if ($doggy =~ /$dogs_re/) {...}

That creates a regex alternation of your dog types, after quoting any regex special characters in the names.

You could compile the regex as well if you want:

$_ = qr/$_/ for $dogs_re;  

which would be placed after the line defining $dogs_re, and may offer some performance benefits if you will be using the regex many times.

Answer 6

I would probably choose the hash lookup solution for best answer, but there are many ways to do this. This is one of them.

Note that this uses our dog name as the regex and iterates it over the list instead of the other way around.

use v5.10; # needed for say
@dogs=qw(Shepherd Lab Poodle Foo Bar); 
$dog = 'Lab'; 
/\Q$dog\E/i and say for @dogs;"

You can control how strict the match is:

/\Q$dog\E/i is least strict, ignore case, match anywhere in word. E.g. "lab" will match "Yellow Lab", "Labrador" etc.

/^\Q$dog\E$/ is most strict, match case, match entire word.

Answer 7

Try this,

$" = "|";
my @dogs=qw(Shepherd Lab Poodle Foo Bar);
my $temp = "@dogs";
my $dog = "Lab";
print "$1 found" if ($dog =~ /($temp)/);