How can I process a file two lines at a time in Perl?

Question

I have a signal file with each line beginning with 0 or 1.

If I have 1 followed by 0 in the next line, then I need to process the 0 signal line.

>#Sample File

>0

>0

>1

>0 (process line)

>0

>1

>0 (process line)

my code

 OUTER : while (<F>) {
   if($_=~/1/){
     my $a = <F>
     process_line($a) if ($a=~/0/);
     next OUTER if ($a=~/1/);
   }

The file is huge, so I don't want to slurp.

Is there more data on each line? Could the extra data contain 0's and 1's too? If so, then your regex needs to be anchored to the start of the line. — Jonathan Leffler, Nov 26 '11 at 12:11

score 4 · Accepted Answer · 2011-11-26T16:34:31.880

4

Something like:

#!/usr/bin/perl

use strict;
use warnings;
my $prevLine = "";

sub processline {
    my $line = shift;
    $line =~ s@^0 @@;
    print $line;
}

while (<DATA>) {
    if ($_ =~ /^0/ && $prevline =~ /^1/) {
        processline($_);
    }
    $prevLine = $_;
}

__DATA__
0
0
1
0 (process line)
0
1
0 (process line)

Output

(process line)
(process line)

edited Nov 26 '11 at 16:34

answered Nov 26 '11 at 12:11

Corrected the regexp, for/while and var case parts. Thanks for the clarifications. – Nov 26 '11 at 16:35

score 1 · Answer 2 · edited May 23 '17 at 10:34

I see the possible error with your code: Two or more consecutive lines starting with 1 will misfire and skip a match.

while (<>) {
   if(/^1/){            # Ignore everything except 1-lines
      while (<>) {      # Start inner loop
         next if /^1/;  # Skipping consecutive 1-lines
         die "Bad line: $_" unless /^0/;  # Anything not 1 or 0 is not allowed
         process_line($_);
         last;          # Exit inner loop, search for next 1-line
      }
   }
}

Usage options:

script.pl filename        (single file)
script.pl filename*       (glob, multiple files)
some_command | script.pl

Changes:

Global filehandle changed to diamond operator, works on STDIN or filename arguments to the script. If you want an explicit open, use open my $fh, '<', $filename or die $!
Added anchors in the regexes to match beginning of string only, e.g. /^1/
Removed unnecessary label OUTER. next and last will affect the innermost loop only (see perldoc -f last).
$_ =~ /^1/ changed to /^1/, which is equivalent, and more legible.
Nested use of $_ is valid, and will work as expected. If you want, the inner loop can use another variable, e.g. while (my $line = <>), which may be seem less confusing to some. (Not to me, though)

You should use strict and warnings, if you are not already doing so. Why use strict and warnings?

score 0 · Answer 3 · answered Nov 26 '11 at 16:48

0

Another variation:

#!/usr/bin/env perl
use strict;
use warnings;
sub processme {
    my $line = shift;
    print $line;
}
while (<>) {
    if (/^1/../^0/) {
        processme( $_ ) if /^0/;
    }
}

answered Nov 26 '11 at 16:48

JRFerguson

7,426
2
32
36

How can I process a file two lines at a time in Perl?

3 Answers3