How to allow or forbid user to enter tab in pagecontrol?

Question

I want to restrict users (based on special condition) to open a tab or not in a page control. ie, the user can click on the tab but it will not be displayed to him. Instead, a message will show to him that "he don't have the access right to see such tab".

On what event I should write the checking code, and what tab property (of TPageControl component) will allow/block user to enter such tab?

Why show the tab in the first place if the user can't see the contents anyway?? — whosrdaddy, Dec 05 '11 at 12:11
Can you please explain in more details the scenario that is occurring? We could then suggest best practices for security and GUI standards for your task. — Marcus Adams, Dec 05 '11 at 14:54
sure, I'm designing an employee screen which has personal Info, his contract info and family information each of them in diffrenet tab. so the super user with the priviliges can see the contract info but another user with less priviliges must see only the family inf and edit it but not his contract inf (like salary , allowances..etc). please if you have better design in mind, you will save my life (and my work) . thank you all — Amanda, Dec 06 '11 at 02:39

score 7 · Answer 1 · answered Dec 05 '11 at 11:06

In an ideal world you would set AllowChange to False from theOnChanging event to block a page change. However, this does not appear to be viable because I can find no way of discerning, from within OnChanging, which page the user is trying to select.

Even looking at the underlying Windows notification seems to offer little hope. The TCN_SELCHANGING notification identifies the control, but not says nothing about the pages involved, so far as I can tell.

The best I can come up with is to use OnChanging to note the current active page and then do the hard work in OnChange. If the selected page has been changed to something undesirable, then just change it back.

procedure TForm1.PageControl1Changing(Sender: TObject; var AllowChange: Boolean);
begin
  FPreviousPageIndex := PageControl1.ActivePageIndex;
end;

procedure TForm1.PageControl1Change(Sender: TObject);
begin
  if PageControl1.ActivePageIndex=1 then begin
    PageControl1.ActivePageIndex := FPreviousPageIndex;
    Beep;
  end;
end;

Rather messy I know, but it has the virtue of working!

Doesn't work if you change de activePageIndex in code like self.PageControl1.ActivePageIndex:= 1; — Ravaut123, Dec 05 '11 at 12:07
@Ravaut123 Indeed not. Since you control the code you write, it should be easy to avoid making such an error. — David Heffernan, Dec 05 '11 at 12:09

score 3 · Answer 2 · answered Dec 05 '11 at 19:29

The OnChanging event does not allow you to determine which tab is being selected, because Windows itself does not report that information. What you can do, however, is subclass the TPageControl.WindowProc property to intercept messages that are sent to the TPageControl before it processes them. Use mouse messages to determine which tab is being clicked on directly (look at the TPageControl.IndexOfTabAt() method), and use keyboard messages to detect left/right arrow presses to determine which tab is adjacent to the active tab (look at the TPageControl.FindNextPage() method).

Ravaut123 · Answer 3 · 2011-12-05T17:15:53.537

Use the OnChanging event of the page control.

procedure TForm1.PageControl1Changing(Sender: TObject; var AllowChange: Boolean);
begin
  if (self.PageControl1.TabIndex= 1)and
     (NotAllowUser = 'SomePerson') then
  begin
    AllowChange:= False;
    ShowMessage('Person not allow for this Tab');
  end;
 end;

Ok, the PageControle1.TabIndex is the activepageindex and not the one i want to select. How can i get the clicked Page.

procedure TForm1.PageControl1Changing(Sender: TObject; var AllowChange: Boolean);
var
  P: TPoint;
  NewTabIndex: Integer;
begin

  P := PageControl1.ScreenToClient(Mouse.CursorPos);
  NewTabIndex := PageControl1.IndexOfTabAt(P.X, P.y);

  if (NewTabIndex= 1) then
  begin
    AllowChange:= false;
    Beep
  end;
end;

New Attempt

 TMyPageControl = Class(TPageControl)
 private
   FNewTabSheet: TTabSheet;
   FOnMyChanging: TMyTabChangingEvent;
   procedure SetOnMyChanging(const Value: TMyTabChangingEvent);
   procedure CNNotify(var Message: TWMNotify); message CN_NOTIFY;
   procedure CMDialogKey(var Message: TCMDialogKey); message CM_DIALOGKEY;
 protected
   function CanChange: Boolean; Override;
 public
   property OnMyChanging: TMyTabChangingEvent read FOnMyChanging write SetOnMyChanging;
 End;



 { TMyPageControl }




 function TMyPageControl.CanChange: Boolean;
 begin
   Result := True;
   if Assigned(FOnMyChanging) then FOnMyChanging(Self, FNewTabSheet ,Result);
 end;



 procedure TMyPageControl.CMDialogKey(var Message: TCMDialogKey);
 begin
   if (Focused or Windows.IsChild(Handle, Windows.GetFocus)) and
      (Message.CharCode = VK_TAB) and (GetKeyState(VK_CONTROL) < 0) then
   begin
     FNewTabSheet := FindNextPage(ActivePage, GetKeyState(VK_SHIFT) >= 0,True);
     SelectNextPage(GetKeyState(VK_SHIFT) >= 0);
     Message.Result := 1;
   end else
    inherited;
 end;

 procedure TMyPageControl.CNNotify(var Message: TWMNotify);
 var
   P: TPoint;
   NewTabIndex: Integer;
 begin
     with Message do
     case NMHdr.code of
       TCN_SELCHANGE:
         Change;
       TCN_SELCHANGING:
         begin
           Result := 1;
             P := self.ScreenToClient(Mouse.CursorPos);
            NewTabIndex := self.IndexOfTabAt(P.X, P.y);
            FNewTabSheet:= self.Pages[NewTabIndex];
           if CanChange then Result := 0;
         end;
     end;
 end;

 procedure TMyPageControl.SetOnMyChanging(const Value: TMyTabChangingEvent);
 begin
   FOnMyChanging := Value;
 end;

That won't work as requested, as the TabIndex property will give you the index of the currently active tab during the OnChanging event instead of the newly selected tab. — Uwe Raabe, Dec 05 '11 at 11:04
Sadly this does not work because TabIndex is the currently selected page rather than the page that the user is trying to select — David Heffernan, Dec 05 '11 at 11:05
I change the code to get the selected PageIndex that the user wants. — Ravaut123, Dec 05 '11 at 15:16
@Ravault - It's also possible to switch to a new tab with Ctrl+Tab or using the arrows when a tab button is active. — Sertac Akyuz, Dec 05 '11 at 16:30
@Sertac do you know if the information we seek can be obtained in TVN_SELCHANGING? — David Heffernan, Dec 05 '11 at 16:47
@David - No, I agree with your assessment in your answer. I don't like the solution though.. — Sertac Akyuz, Dec 05 '11 at 17:00
There remains arrows for nit-picking I think, but Ok point taken, it's workable deriving a new control.. — Sertac Akyuz, Dec 05 '11 at 18:40

Smilko · Answer 4 · 2023-01-18T11:11:44.620

1

You can show tab and effectively disable changing in OnChanging event of TPageControl. All you need to do is set AllowChange var to False.

procedure TForm1.PageControl1(Sender: TObject; var AllowChange: Boolean); 
begin
    AllowChange := MyCondition;
    if MyCondition
        ShowMessage('User doesn''t have permission to see this tab.');
end

edited Jan 18 '23 at 11:11

answered Jan 18 '23 at 11:04

Smilko

43
7

score 0 · Answer 5 · edited Jul 24 '14 at 16:46

0

Sometimes it is better just to hide unwanted TabSheets with something like this:

TabSheetNN.TabVisible:=Somecondition;

than trying to prevent switching to these tabs. Sure, it would be better if Sender in OnChanging event will be TabSheet , not TPageControl.

edited Jul 24 '14 at 16:46

margabit

2,924
18
24

answered Jul 24 '14 at 16:38

user1651471

1

How to allow or forbid user to enter tab in pagecontrol?

5 Answers5

Linked