Extracting specific lines with Perl

Question

I am writing a perl program to extract lines that are in between the two patterns i am matching. for example the below text file has 6 lines. I am matching load balancer and end. I want to get the 4 lines that are in between.

**load balancer** 
new 
old
good
bad
**end**

My question is how do you extract lines in between load balancer and end into an array. Any help is greatly appreciated.

Did you mean that `**` should be in the actual input file, or is that a formatting mistake? — TLP, Dec 08 '11 at 18:47
People don't know how fast SO users reply to their questions. =) — TLP, Dec 08 '11 at 18:53

TLP · Answer 1 · 2014-08-13T23:54:02.387

7

You can use the flip-flop operator to tell you when you are between the markers. It will also include the actual markers, so you'll need to except them from the data collection.

Note that this will mash together all the records if you have several, so if you do you need to store and reset @array somehow.

use strict;
use warnings;

my @array;
while (<DATA>) {
    if (/^load balancer$/ .. /^end$/) {
        push @array, $_ unless /^(load balancer|end)$/;
    }
}

print @array;

__DATA__
load balancer
new 
old
good
bad
end

edited Aug 13 '14 at 23:54

answered Dec 08 '11 at 18:38

TLP

66,756
10
92
149

Sweet, didnt know you can use the flip flip op like this. – snoofkin Dec 08 '11 at 19:55
@abhirampotluri You're welcome. If you feel this answered your question, click the check mark (to the left) to mark it as correct. – TLP Dec 08 '11 at 21:44
@abhirampotluri Is there a reason you chose not to accept my answer, and instead chose a lower rated answer that came in after mine, which does not save the result into an array? I noted that you first accepted mine, then changed your mind. – TLP Dec 10 '11 at 01:22
@Miller You cant just rewrite my entire answer to suit a duplicate pointing to this question. If its not the same answer, then its not the same question. And I don't think that was really simplifying logic, rather the opposite. Maybe you meant making the code more generic. – TLP Aug 13 '14 at 23:55

score 2 · Accepted Answer · edited Aug 14 '14 at 08:51

2

You can use the flip-flop operator.

Additionally, you can also use the return value of the flipflop to filter out the boundary lines. The return value is a sequence number (starting with 1) and the last number has the string E0 appended to it.

# Define the marker regexes separately, cuz they're ugly and it's easier
# to read them outside the logic of the loop.
my $start_marker = qr{^ \s* \*\*load \s balancer\*\* \s* $}x;
my $end_marker   = qr{^ \s* \*\*end\*\* \s* $}x;

while( <DATA> ) {
    # False until the first regex is true.
    # Then it's true until the second regex is true.
    next unless my $range = /$start_marker/ .. /$end_marker/;

    # Flip-flop likes to work with $_, but it's bad form to
    # continue to use $_
    my $line = $_;

    print $line if $range !~ /^1$|E/;
}

__END__
foo
bar
**load balancer** 
new 
old
good
bad
**end**
baz
biff

Outputs:

new 
old
good
bad

edited Aug 14 '14 at 08:51

Miller

34,962
4
39
60

answered Dec 08 '11 at 18:39

Schwern

153,029
25
195
336

I think the `**` was actually Markup that was unintentionally included by using the code formatting. – TLP Dec 08 '11 at 18:43
1

@TLP Left as an exercise for the reader. Let's call it cut & paste defense. :) – Schwern Dec 08 '11 at 18:45
@TLP: you are right. I was trying to format the charecters to bold and it happened like that. sorry.!! – abhiram potluri Dec 08 '11 at 21:38

score 0 · Answer 3 · answered Dec 08 '11 at 19:10

0

If you prefer a command line variation:

perl -ne 'print if m{\*load balancer\*}..m{\*end\*} and !m{\*load|\*end}' file

answered Dec 08 '11 at 19:10

JRFerguson

7,426
2
32
36

Axeman · Answer 4 · 2011-12-08T20:11:22.640

0

For files like this, I often use a change in the Record Separator ( $/ or $RS from English )

use English qw<$RS>;
local $RS = "\nend\n";

my $record = <$open_handle>;

When you chomp it, you get rid of that line.

chomp( $record );

edited Dec 08 '11 at 20:11

answered Dec 08 '11 at 20:06

Axeman

29,660
2
47
102

Extracting specific lines with Perl

4 Answers4

Linked

Related