GNU clisp: suppressing warning message about no-applicable-method

Question

This code works as I want, except for the warning message. In GNU Common Lisp, how do I suppress that message without suppressing other possible warning messages?

 1 (defgeneric zang (x y)
 2   (:documentation "they want you to put documentation here"))
 3 (defmethod zang ((a number) (b string))
 4   (format t "got to zang ((~s number) (~s string))~%" a b))
 5 (defmethod zang ((a integer) (b string))
 6   (format t "got to zang ((~s integer) (~s string))~%" a b)
 7   (when (evenp a)
 8     (format t "passing control to the other guy~%")
 9     (call-next-method (1+ a) "hoo boy")
10     (format t "returned control from the other guy~%")))
11 (defmethod no-applicable-method (zang &rest args)
12   (format t "no applicable method for (zang ~{~s~^ ~})~%" args))
13 (zang 3.5 "hi")
14 (zang 3 "hi")
15 (zang 4 "hi")
16 (zang "hello" "world")
WARNING: Replacing method #<STANDARD-METHOD (#<BUILT-IN-CLASS T>)> in
         #<STANDARD-GENERIC-FUNCTION NO-APPLICABLE-METHOD>
got to zang ((3.5 number) ("hi" string))
got to zang ((3 integer) ("hi" string))
got to zang ((4 integer) ("hi" string))
passing control to the other guy
got to zang ((5 number) ("hoo boy" string))
returned control from the other guy
no applicable method for (zang "hello" "world")

EDIT in response to Vatine's kind reply:

I tried that, and the situation escalated from a warning to a fatal error:

 (defgeneric zang (x y)
   (:documentation "they want you to put documentation here"))
 (defmethod zang ((a number) (b string))
   (format t "got to zang ((~s number) (~s string))~%" a b))
 (defmethod zang ((a integer) (b string))
   (format t "got to zang ((~s integer) (~s string))~%" a b)
   (when (evenp a)
     (format t "passing control to the next guy~%")
     (call-next-method (1+ a) "hoo boy")
     (format t "returned control from the next guy~%")))
 ;(defmethod no-applicable-method (zang &rest args)
 ;  (format t "no applicable method for (zang ~{~s~^ ~})~%" args))
 (defmethod no-applicable-method ((zang eql #'zang) &rest args)
   (format t "no applicable method for (zang ~{~s~^ ~})~%" args))
 (zang 3.5 "hi")
 (zang 3 "hi")
 (zang 4 "hi")
 (zang "hello" "world")
*** - DEFMETHOD NO-APPLICABLE-METHOD: Invalid specialized parameter in method
      lambda list ((ZANG EQL #'ZANG) &REST ARGS): (ZANG EQL #'ZANG)

Do you want to suppress "Replacing method" warning or not print "no applicable method"? — Vsevolod Dyomkin, Dec 15 '11 at 12:51
I wish to suppress the two lines beginning with "WARNING: Replacing method". — Bill Evans at Mariposa, Dec 15 '11 at 13:27

score 4 · Accepted Answer · answered Dec 15 '11 at 23:17

You need to provide a correct argument list for NO-APPLICABLE-METHOD. If you use a compiler (even the CLISP implementation can compile via COMPILE-FILE), you also should get an error message at compile time about the incorrect argument list.

The LispWorks compiler for example says:

**++++ Error between functions:
 An argument is not an atom or list of two elements : (ZANG EQL (FUNCTION ZANG))

Fixed version:

(defgeneric zang (x y)
   (:documentation "they want you to put documentation here"))
(defmethod zang ((a number) (b string))
   (format t "got to zang ((~s number) (~s string))~%" a b))
(defmethod zang ((a integer) (b string))
   (format t "got to zang ((~s integer) (~s string))~%" a b)
   (when (evenp a)
     (format t "passing control to the next guy~%")
     (call-next-method (1+ a) "hoo boy")
     (format t "returned control from the next guy~%")))
;(defmethod no-applicable-method (zang &rest args)
;  (format t "no applicable method for (zang ~{~s~^ ~})~%" args))

(defmethod no-applicable-method ((zang (eql #'zang)) &rest args)
   (format t "no applicable method for (zang ~{~s~^ ~})~%" args))

Example:

(defun test ()
 (zang 3.5 "hi")
 (zang 3 "hi")
 (zang 4 "hi")
 (zang "hello" "world"))

CL-USER 1 > (test)
got to zang ((3.5 number) ("hi" string))
got to zang ((3 integer) ("hi" string))
got to zang ((4 integer) ("hi" string))
passing control to the next guy
got to zang ((5 number) ("hoo boy" string))
returned control from the next guy
no applicable method for (zang "hello" "world")
NIL

This worked! My ability to understand the documentation isn't null, but it isn't perfect, either. This example of correct syntax will help me as I go back to the documentation. Thank you! — Bill Evans at Mariposa, Dec 15 '11 at 23:51
To be clear: part of the solution is that the second "zang" in the replacement code be spelled as is. But since I'm not actually using that parameter, the first "zang" can be spelled arbitrarily. Example: ((fred (eql 'zang)) — Bill Evans at Mariposa, Dec 16 '11 at 10:47
@Bill Evans at Mariposa: a parameter list like ((zang (eql #'zang)) &rest args) means that the first zang is the parameter name. The EQL part means that for this method to match the actual argument needs to be EQL to the function object of the function zang. This is the second zang. — Rainer Joswig, Dec 20 '11 at 19:43
Yes. thanks. The only reason that the first "zang" can be spelled arbitrarily is that I don't use that first parameter in the body of the method. — Bill Evans at Mariposa, Dec 25 '11 at 12:45

Vatine · Answer 2 · 2011-12-16T12:52:14.553

3

I think you want to define a method on no-applicable-method as:

(defmethod no-applicable-method ((zang (eql #'zang)) &rest args)
   ...)

As-is, you're declaring a method that applies to all generic functions and that's why clisp is telling you that you're replacing an already-defined method.

edited Dec 16 '11 at 12:52

answered Dec 15 '11 at 15:38

Vatine

20,782
4
54
70

I think you're on to something, but that syntax doesn't work; see my edit to the question. Thanks anyway. :) – Bill Evans at Mariposa Dec 15 '11 at 18:03
1

I suspect it needs parentheses around the "eql #'zang" part. – Vatine Dec 16 '11 at 12:50

GNU clisp: suppressing warning message about no-applicable-method

2 Answers2