Awk script to select files and print file sizes

Question

I'm working on a home work assignment. The question is:

Write an awk script to select all regular files (not directories or links) in /etc ending with .conf, sort the result by size from smallest to largest, count the number of files, and print out the number of files followed by the filenames and sizes in two columns. Include a header row for the filenames and sizes. Paste both your script and its output in the answer area.

I'm really struggling trying to get this to work through using awk. Here's what I came up with.

 ls -lrS /etc/*.conf |wc –l

will return the number 33 which is the number of files .conf files in the directory.

 ls -lrS /etc/*.conf |awk '{print "File_Size"": " $5 "   ""File_Name and Size"": " $9}'

this will make 2 columns with the name and size of the .conf file in the directory.

It works, but I don't think it is what he's looking for. I'm having an AWKful time.

I find it pretty awd that your instrawcter is teaching you awk at this late era in Unix history. There are a lot of better ways to write readable scripts, and if your instrawcter insists awn teaching you unreadable styles, then at least you could lawrn perl. — Warren P, Dec 18 '11 at 21:31

score 5 · Accepted Answer · edited May 23 '17 at 10:08

Let's see here...

select all regular files (not directories or links)

So far you haven't addressed this, but if you are piping in the output of ls -l..., this is easy, select on

/^-/

because directories start with d, symbolic links with l and so on. Only plain old files start with -. Now

print out the number of files followed

Well, counting matches is easy enough...

BEGIN{count=0}  # This is not *necessary*, but I tend to put it in for clarity
/^-/ {count++;}

To get the filename and size, look at the output of ls -l and count up columns

BEGIN{count=0}
/^-/ {
  count++;
  SIZE=$5;
  FNAME=$9;
}

The big difficulty here is that awk doesn't provide much by way of sorting primitives, so that's the hard part. That can be beaten if you want to be clever but it is not particularly efficient (see the awful thing I did in a [code-golf] solution). The easy (and unixy) thing to do would be to pipe part of the output to sort, so...we collect a line for each file into a big string

BEGIN{count=0}
/^-/ {
  count++
  SIZE=$5;
  FNAME=$9;
  OUTPUT=sprintf("%10d\t%s\n%s",SIZE,FNAME,OUTPUT);
}
END{
   printf("%d files\n",count);
   printf("  SIZE    \tFILENAME"); # No newline here because OUTPUT has it
   print OUTPUT|"sort -n --key=1";
}

Gives output like

11 files
  SIZE          FILENAME
       673      makefile
      2192      houghdata.cc
      2749      houghdata.hh
      6236      testhough.cc
      8751      fasthough.hh
     11886      fasthough.cc
     19270      HoughData.png
     60036      houghdata.o
    104680      testhough
    150292      testhough.o
    168588      fasthough.o

(BTW--There is a test subdirectory here, and you'll note that it does not appear in the output.)

Very thorough, thank you! The step by step explanation is a huge help. — user1104868, Dec 18 '11 at 20:50

jaypal singh · Answer 2 · 2011-12-18T22:05:06.950

May be something like this should get you on your way -

ls -lrS /etc/*.conf |  
awk '
BEGIN{print "Size:\tFilename:"} # Prints Headers
/^-/{print $5"\t"$9} # Prints two desired columns, /^-/ captures only files
END{print "Total Files = "(NR-1)}' # Uses in-built variable to print count

Test: Text after # are comments for your reference.

[jaypal:~/Temp] ls -lrS /etc/*.conf |  
awk '
BEGIN{print "Size:\tFilename:"}
/^-/{print $5"\t"$9}
END{print "Total Files = "(NR-1)}'
Size:   Filename:
0       /etc/kern_loader.conf
22      /etc/ntp.conf
54      /etc/ftpd.conf
105     /etc/launchd.conf
168     /etc/memberd.conf
242     /etc/notify.conf
366     /etc/ntp-restrict.conf
526     /etc/gdb.conf
723     /etc/pf.conf
753     /etc/6to4.conf
772     /etc/syslog.conf
983     /etc/rtadvd.conf
1185    /etc/asl.conf
1238    /etc/named.conf
1590    /etc/newsyslog.conf
1759    /etc/autofs.conf
2378    /etc/dnsextd.conf
4589    /etc/man.conf
Total Files = 18

score 0 · Answer 3 · answered Dec 18 '11 at 20:18

I would first find the files with something like find /etc -type f -name '*.conf' ; so you get the right list of files. Then you do ls -l on them (perhaps using xargs). And then using awk should be simple.

But I don't think that if I did more your homework that would help you. You need to think by yourself and find out.

score 0 · Answer 4 · answered Dec 18 '11 at 21:02

Disclaimer: I'm not a shell expert.

Thought I'd give this a go, been beaten on speed of reply though :-) :

clear

FILE_COUNT=`find /etc/ -name '*.conf' -type f -maxdepth 1 | wc -l`

echo "Number of files:  $FILE_COUNT"

ls -lrS /etc/[^-]*.conf | awk '

BEGIN {print "NAME     |     SIZE"}\

{print $9,"     |    ",$5}\

END {print "- DONE -"}\

'

My output is ugly :-( :

Number of files:        21
NAME     |     SIZE
/etc/kern_loader.conf      |     0
/etc/resolv.conf      |     20
/etc/AFP.conf      |     24
/etc/ntp.conf      |     42
/etc/ftpd.conf      |     54
/etc/notify.conf      |     132
/etc/memberd.conf      |     168
/etc/Symantec.conf      |     246
/etc/ntp-restrict.conf      |     366
/etc/gdb.conf      |     526
/etc/6to4.conf      |     753
/etc/syslog.conf      |     772
/etc/asl.conf      |     860
/etc/liveupdate.conf      |     861
/etc/rtadvd.conf      |     983
/etc/named.conf      |     1238
/etc/newsyslog.conf      |     1590
/etc/autofs.conf      |     1759
/etc/dnsextd.conf      |     2378
/etc/smb.conf      |     2975
/etc/man.conf      |     4589
/etc/amavisd.conf      |     31925
- DONE -

Pipe through `column -t` to fix the alignment :] – Chris Seymour Dec 17 '12 at 14:19 — Chris Seymour, Dec 17 '12 at 14:19

Awk script to select files and print file sizes

4 Answers4