Enumerate TWebRequest HTTP header fields

Question

is it possible to dump all the header fields of a TWebRequest (and TWebResponse) object? At the moment I use GetFieldByName() and print them with Writeln() but this works only if I already know the name of the header field. I'm looking for a way to obtain all header field names to enumarate each field but I didn't find any method to do that.

I wrote a REST datasnap console application and wants to log all HTTP requests/responses to console.

score 9 · Accepted Answer · answered Dec 29 '11 at 14:27

AFAIK it is not possibile (Delphi XE2).

I've used a little trink to have access to the raw headers. However, this is really dirty! Use at you own risk!

The actual class request class is the TIdHTTPAppRequest (WARNING: Could be different for different type of webbroker app. I''ve not tested this code with different kind of datasnap app).

So the trick is:

Declare a class helper similar to the following:

  TIdHTTPAppRequestHelper = class helper for TIdHTTPAppRequest
  public
    function GetRequestInfo: TIdEntityHeaderInfo;
  end;

  implementation

  function TIdHTTPAppRequestHelper.GetRequestInfo: TIdEntityHeaderInfo;
  begin
    Result := FRequestInfo;
  end;

In this way you can use this helper to have acccess to the protected FRequestInfo field.

In the OnAction event handler you can use the following code to have all the headers names:

procedure Twm.wmWebActionItem1Action(Sender: TObject; Request: TWebRequest;
                 Response: TWebResponse; var Handled: Boolean);
var
  HeadersCount: Integer;
  I: Integer;
  sw: TStreamWriter;
begin
  Response.ContentType := 'text/plain';
  Response.ContentStream := TMemoryStream.Create;
  sw := TStreamWriter.Create(Response.ContentStream);
  try
    HeadersCount := TIdHTTPAppRequest(Request).GetRequestInfo.RawHeaders.Count;
    for I := 0 to HeadersCount - 1 do
      sw.WriteLine(TIdHTTPAppRequest(Request).GetRequestInfo.RawHeaders.Names[I]);
  finally
    sw.Free;
  end;
  Handled := True;
end;

However, it is bad that TWebRequest do not allows to read the raw headers. That should be changed!

If you are using an older version of Delphi that doesn't have the Helpers, since FRequestInfo is protected, you can inherit from TIdHTTPAppRequest and add the GetRequestInfo method to the new class. Has the same caveats as the Helper version. — Toby, Mar 09 '21 at 23:57

Enumerate TWebRequest HTTP header fields

1 Answers1

Linked