I want to sort array of arrays in Perl, but the result is not sorted

Question

I have an array of arrays that I want to sort. Each element of array A is an array with 3 elements. Array A looks like:

my @A = ([2,3,1], [1,2,3], [1,0,2], [3,1,2], [2,2,4]);

I want to sort A in ascending order. When comparing 2 elements, the first number is used. If there is a tie, the second number is used, and then the third number.

Here is my code. I use a function 'cmpfunc' to compare 2 elements.

sub cmpfunc {
    return ($a->[0] <=> $b->[0]) or 
           ($a->[1] <=> $b->[1]) or
           ($a->[2] <=> $b->[2]);
}
my @B = sort cmpfunc @A;
print "Result:\n";
for my $element (@B) {
    print join(",", @{$element}) . "\n";
}

Result:

1,2,3
1,0,2
2,3,1
2,2,4
3,1,2

The result is somewhat sorted, but not correct. What I expect is:

1,0,2
1,2,3
2,2,4
2,3,1
3,1,2

Is there any error in my comparison function? The strange thing is, when I put the comparison code in block, the result is correctly sorted.

my @C = sort { ($a->[0] <=> $b->[0]) or 
               ($a->[1] <=> $b->[1]) or
               ($a->[2] <=> $b->[2]) } @A;

Related: http://stackoverflow.com/questions/1512547 – mob Jan 13 '12 at 15:49 — mob, Jan 13 '12 at 15:49

score 23 · Accepted Answer · edited Feb 20 '17 at 14:21

23

You are executing

return ($a->[0] <=> $b->[0])

which returns before it gets to any of the "or" clauses.

Either remove the "return" keyword, or add parenthesis around the entire arg list for return:

sub cmpfunc {
    return(($a->[0] <=> $b->[0]) or
           ($a->[1] <=> $b->[1]) or
           ($a->[2] <=> $b->[2]));
}

edited Feb 20 '17 at 14:21

Cœur

37,241
25
195
267

answered Jan 13 '12 at 13:02

tadmc

3,714
16
14

9

*OR* use the tighter-binding or: `||`. – Axeman Jan 13 '12 at 14:21

score 11 · Answer 2 · answered Jan 13 '12 at 13:04

The reason you observe this "wrong" behavior is the priority of or operator, the lowest possible. In this situation it means that

return ($a->[0] <=> $b->[0]) or 
       ($a->[1] <=> $b->[1]) or
       ($a->[2] <=> $b->[2]);

is interpreted as OR-ing

return ($a->[0] <=> $b->[0])

and the rest of the line -- nonsense in this case, as return never returns. :)

So you should use C's OR:

return ($a->[0] <=> $b->[0]) || 
       ($a->[1] <=> $b->[1]) ||
       ($a->[2] <=> $b->[2]);

score 7 · Answer 3 · answered Jan 13 '12 at 13:00

7

Needs more parentheses:

sub cmpfunc {
    return (($a->[0] <=> $b->[0]) or
            ($a->[1] <=> $b->[1]) or
            ($a->[2] <=> $b->[2]));
}

answered Jan 13 '12 at 13:00

Daniel Fischer

181,706
17
308
431

score 5 · Answer 4 · answered Jan 13 '12 at 13:05

5

    sub cmpfunc {
    return ($a->[0] <=> $b->[0]) or 
           ($a->[1] <=> $b->[1]) or
           ($a->[2] <=> $b->[2]);
}

you can delete 'return' here.

    sub cmpfunc {
     ($a->[0] <=> $b->[0]) or 
     ($a->[1] <=> $b->[1]) or
     ($a->[2] <=> $b->[2]);
}

answered Jan 13 '12 at 13:05

timest

188
2
9

It will still return the first statement that evaluates true. – Leonardo Herrera Jan 13 '12 at 13:20
1

@LeonardoHerrera It is supposed to do that. – TLP Jan 13 '12 at 13:30

flesk · Answer 5 · 2012-01-13T18:59:52.380

An alternative solution to Daniel's:

sub cmpfunc {
    return ($a->[0] <=> $b->[0]) ||
           ($a->[1] <=> $b->[1]) ||
           ($a->[2] <=> $b->[2]);
}

The problem with or this case is that it has lower precedence than assignment, so your function only returns the result of ($a->[0] <=> $b->[0]), which is -1, 0 or 1 if the left hand side is numerically lower than, equal to or larger than the right hand side respectively. || has higher precedence, so the entire boolean expression is evaluated before returning. As mentioned, you can wrap the expression in parentheses if you prefer that to ||. I personally don't.

Actually, it returns only the first comparison, no matter what it returns. Try `sub a { return 0 or die "Ough" }`. — TLP, Jan 13 '12 at 13:34

I want to sort array of arrays in Perl, but the result is not sorted

5 Answers5