Yank file name / path of current buffer in Vim

Question

Assuming the current buffer is a file open for edit, so :e does not display E32: No file name.

I would like to yank one or all of:

The file name exactly as show on the status line, e.g. ~\myfile.txt
A full path to the file, e.g. c:\foo\bar\myfile.txt
Just the file name, e.g. myfile.txt

Similar to http://stackoverflow.com/q/741024/80161 and http://stackoverflow.com/q/2233905/80161 — Nathan Hartley, May 31 '11 at 19:50
To clipboard: http://vi.stackexchange.com/questions/3686/copy-the-full-path-of-current-buffer-to-clipboard — Ciro Santilli OurBigBook.com, Oct 20 '15 at 08:53

score 280 · Accepted Answer · edited Aug 21 '23 at 18:31

280

TL;DR

:let @" = expand("%")

this will copy the file name to the unamed register, then you can use good old p to paste it. and of course you can map this to a key for quicker use.

:nmap cp :let @" = expand("%")<cr>

you can also use this for full path

:let @" = expand("%:p")

Explanation

Vim uses the unnamed register to store text that has been deleted or copied (yanked), likewise when you paste it reads the text from this register.

Using let we can manually store text in the register using :let @" = "text" but we can also store the result of an expression.

In the above example we use the function expand which expands wildcards and keywords. in our example we use expand('%') to expand the current file name. We can modify it as expand('%:p') for the full file name.

See :help let :help expand :help registers for details

edited Aug 21 '23 at 18:31

Razzi Abuissa

3,337
2
28
29

answered Jun 05 '09 at 05:01

JD Frias

4,418
3
21
24

29

Cool just added this to my vimrc: noremap :let @+=expand("%:p") – ThePosey Mar 17 '11 at 14:42
13

On Windows, you should instead use :let @* = expand("%"), if you want it to be in the _Windows_ clipboard. – KFL Sep 11 '13 at 21:36
28

If you are using `unnamedplus` as your clipboard use `let @+ = expand("%")` – Kevin Cox May 15 '14 at 21:18
4

Use `"%:h"` to get the full path without the filename. – Polymorphix Aug 18 '15 at 09:05
Related, in particular if you need the directory without filename - https://stackoverflow.com/a/2233924/1882064 – arcseldon Oct 30 '17 at 22:39
Is there any reason why one wouldn't just use the `%` register? ie `"%p` ? – shangxiao Feb 01 '19 at 01:33

score 127 · Answer 2 · edited Feb 06 '23 at 23:10

127

Almost what you're asking for, and it might do: in INSERT mode, Ctrl+R % pulls the current filename into where you are (command prompt, edit buffer, ...). See this Vim Tip for more.

edited Feb 06 '23 at 23:10

toraritte

6,300
3
46
67

answered May 27 '09 at 17:05

dwc

24,196
7
44
55

1

when you exit edit mode you can add the file name: ctrl-" ctrl-% p – stefanB Jun 05 '09 at 05:09
24

`Ctrl+R %` works while in `insert` mode -- but in `edit` mode, `Ctrl+R` means redo. – Kevin Panko Jan 26 '10 at 22:16
4

What stefanB meant was "%p for normal/command mode. That's the same as % in insert/cmdline-mode. – graywh Feb 01 '10 at 17:00
1

Just to resummarize or state differently: the answers for both graywh and dwc are "paste from register %". One does this for insert mode, the other for normal mode. In macvim, it appears the % register can't be overwritten. – Eric Hu Jun 07 '12 at 20:24
is there the same simple command to get linenumber ? ) thx for solution – itsnikolay May 15 '14 at 06:20
This only gets filename not complete path. – WestCoastProjects Feb 02 '16 at 20:24

score 114 · Answer 3 · edited May 23 '17 at 11:54

If you want to put the current buffer filename in your system-level clipboard, try changing the register to @+:

" relative path
:let @+ = expand("%")

" full path
:let @+ = expand("%:p")

" just filename
:let @+ = expand("%:t")

Edit 20140421: I commonly use these, so I created some shortcuts. Linux Vims apparently operate slightly differently than Mac Vims, so there is a special case for that as well. If you put the following in your ~/.vimrc:

" copy current file name (relative/absolute) to system clipboard
if has("mac") || has("gui_macvim") || has("gui_mac")
  " relative path  (src/foo.txt)
  nnoremap <leader>cf :let @*=expand("%")<CR>

  " absolute path  (/something/src/foo.txt)
  nnoremap <leader>cF :let @*=expand("%:p")<CR>

  " filename       (foo.txt)
  nnoremap <leader>ct :let @*=expand("%:t")<CR>

  " directory name (/something/src)
  nnoremap <leader>ch :let @*=expand("%:p:h")<CR>
endif

" copy current file name (relative/absolute) to system clipboard (Linux version)
if has("gui_gtk") || has("gui_gtk2") || has("gui_gnome") || has("unix")
  " relative path (src/foo.txt)
  nnoremap <leader>cf :let @+=expand("%")<CR>

  " absolute path (/something/src/foo.txt)
  nnoremap <leader>cF :let @+=expand("%:p")<CR>

  " filename (foo.txt)
  nnoremap <leader>ct :let @+=expand("%:t")<CR>

  " directory name (/something/src)
  nnoremap <leader>ch :let @+=expand("%:p:h")<CR>
endif

Then for example <leader>cf will copy the relative path of the current buffer (the default leader is backslash (\)). I often use these for running commands on a file or doing other things on the command line. I don't really use the last filename / directory name often.

You might consider more intuitive mappings like <leader>cfr for relative, <leader>cfa for absolute, <leader>cff for just filename, <leader>cfd for directory.

On windows and mac `"*` and `"+` are equivalent, so you can dispense with the platform checks and just use `@+` — Gabe Moothart, Aug 27 '14 at 21:53
Oddly enough this doesn't seem to work in a vimscript function: "echo bufname('%:p')" is blank, but you can fix this with the longer "fnamemodify(bufname('%'),':p')" — David Ljung Madison Stellar, Feb 11 '15 at 17:19
Perfect. The key maps are logical. It's portable. Grabs anything out of the path you should want — Zach_is_my_name, Sep 14 '20 at 19:34

score 18 · Answer 4 · edited Dec 10 '21 at 12:26

18

Answer tested on Neovim/Ubunutu.

:let @+=@%

From what I can tell, the % register already contains the relative filepath, so it's as simple as moving the contents of the % register to whatever register represents your favourite clipboard.

This SO answer deals with copying from one register to another

Seems pretty straightforward to me. No need for any hard-to-remember expand() stuff.

edited Dec 10 '21 at 12:26

Chris Stryczynski

30,145
48
175
286

answered Oct 06 '20 at 11:54

LondonRob

73,083
37
144
201

score 12 · Answer 5 · answered Mar 03 '16 at 09:42

If you do :reg you will see the name of the current file in the % register. You can paste it with "%p, for example.

If, like me, you often switch to the 'alternate' buffer, it is very handy that its full path-and-file-name are put in the # register. You can paste it with "#p, for example.

Note (just in case this is behaviour specific to my setup): I am using VIM 7.4.52 on Ubuntu 14.04.4 LTS.

score 4 · Answer 6 · edited Jun 20 '20 at 09:12

Combining information from a couple of other answers: If you want to yank the current full path to a file and put it into the command buffer in another window, first do :let @" = expand("%:p"), then move to another window and type Ctrl+R ".

Useful for copying a file while staying in the same directory and keeping the old one open. For example:

Start: Editing src/com/benatkin/paint/shapes/Circle.java

Type :let @" = expand("%:p") (The path gets yanked to the main clipboard buffer.)

Open a new window with :sp

Type :e Ctrl+R"

Use the arrow keys to go back to Circle and change it to Square, and press <CR>

End: Editing src/com/benatkin/paint/shapes/Square.java

score 3 · Answer 7 · answered Jun 28 '22 at 13:22

If you're on terminal vim, and want to copy to system clipboard: For something easy to remember, that doesn't requiring predefined mappings/functions:

:!echo %

prints the current buffer's relative path to terminal, where you can copy it and then ENTER back to vim. (as already mentioned, you can postfix the command with :p or :t to get absolute or basename, if you can remember that....)

score 2 · Answer 8 · answered May 12 '16 at 16:08

Here is my solution:

" filename / dirname of the current file {{{
    " copy result to the system clipboard and echo the result
    " the cb> prompt means the clipboard
    " *f*ile *n*ame, ex. init.vim
    map <Leader>fn :let @+ = expand("%:t") \| echo 'cb> ' . @+<CR>
    " *f*ile *p*ath, ex. /home/user/nvim/init.vim
    map <Leader>fp :let @+ = expand("%:p") \| echo 'cb> ' . @+<CR>
    " *d*irectory *p*ath, ex. /home/user/nvim
    map <Leader>dp :let @+ = expand("%:p:h") \| echo 'cb> ' . @+<CR>
    " *d*irectory *n*ame, ex. nvim
    map <Leader>dn :let @+ = expand("%:p:h:t") \| echo 'cb> ' . @+<CR>
" }}}

score 0 · Answer 9 · answered Mar 01 '22 at 15:20

0

I put it in my vimc:

nnoremap yl :let @" = expand("%:p")<cr>

answered Mar 01 '22 at 15:20

Good Pen

625
6
10

score 0 · Answer 10 · answered Apr 13 '23 at 11:46

As an alternative to other answers, if you happen to have vim-fugitive installed, you can use default y<C-G> (that's y followed by Ctrl+g) mapping.

From :help vim-fugitive:

                                                *fugitive_y_CTRL-G*
["x]y<C-G>              Yank the path to the current |fugitive-object|.

Even though it specifies fugitive-object it actually works on usual files too, yanking file path.

For me it's even simpler to remember than having to remember how to use expand. And there's no need to create extra mapping.

score 0 · Answer 11 · answered Jul 25 '23 at 19:11

Rather than using map commands (:h map-commands), this might be an ideal application for using abbreviations (:h abbreviations). They behave like TextExpander, but are native to Vim.

Start by adding the following lines to $MYVIMRC. Change the trigger (the <y..> to suit your preferences.

cabbrev yfn   :let @+ = expand("%:t")
cabbrev yfp   :let @+ = expand("%:p")
cabbrev yrp   :let @+ = expand("%")

Using $MYVIMRC as an example:

yfn — %:t tail (filename, last path component only); e.g. cwd: ~/<any/dir>/, result: .vimrc
yfp — %:p expand to full path; e.g. cwd: ~/any/dir/, result: /Users/<home_dir>/.vimrc
yrp — % current file name (relative path); e.g. cwd: ~/, result: .vimrc

So, in command-line mode, <:cabbrev> + <CR> executes the command immediately, or you can start editing it right away.

score -1 · Answer 12 · edited Oct 02 '13 at 21:21

-1

I use xclip to access X's clipboard, so I use:

nmap <localleader>d :call system("xclip -i -selection clipboard", expand("%:p"))<CR>

edited Oct 02 '13 at 21:21

glts

21,808
12
73
94

answered Oct 02 '13 at 20:44

user189557

169
1
3

"+ or "* do the same thing natively in vim without having to use an external command. – Dorian B. Aug 18 '19 at 01:09

score -1 · Answer 13 · answered Sep 30 '21 at 11:11

-1

If you wish to simply yank the path of the currently open file name then simply press:

step1: ctrl + g [You will see the entire root path at the bottom of window]
step2: select the path with the mouse
step3: Paste with the middle mouse wheel

answered Sep 30 '21 at 11:11

Sourabh Tapas

21
5

Yank file name / path of current buffer in Vim

13 Answers13

Linked