How to replace all spaces by underscores in all file names of a folder?

Question

I'm trying to rename all the files inside a folder (all .exe files). I want to replace all the spaces with underscores, e.g. qwe qwe qwe asd.exe to qwe_qwe_qwe_asd.exe.

I need to do this using the command line. I tried a lot of possible solutions I found on internet and even on this site, but I can't make it work.

I also need to do this in "one single line" / "one command", but I'll accept all the working answers.

score 69 · Accepted Answer · answered Dec 26 '13 at 21:58

69

A one liner

cmd /e:on /v:on /c "for %f in ("* *.exe") do (set "n=%~nxf" & set "n=!n: =_!" & ren "%~ff" "!n!" )"

Spawn a cmd instance, with extensions and delayed expansion enabled, and for each exe file with spaces in name, replace spaces with underscores and rename the file with the new name

answered Dec 26 '13 at 21:58

MC ND

69,615
8
84
126

1

How do you modify this to do it recursively through subfolders? – AlexR Sep 14 '19 at 02:33
1

@AlexR, replace `for %f` by `for /r %f`… – aschipfl Nov 18 '20 at 20:14
@Champion Perfect Solution – Muhammad Saad Dec 16 '21 at 17:08
How do you run this in batch file? thanks! – Herbert Yeo Sep 01 '23 at 03:48

score 24 · Answer 2 · edited May 23 '17 at 12:34

24

Adapted from here:

https://stackoverflow.com/a/16129486/2000557

@echo off
Setlocal enabledelayedexpansion

Set "Pattern= "
Set "Replace=_"

For %%a in (*.exe) Do (
    Set "File=%%~a"
    Ren "%%a" "!File:%Pattern%=%Replace%!"
)

Pause&Exit

Create a batch file (*.bat) with the above contents. Place that batch file in the folder with all the .exe's and it will replace the spaces with underscores when you run it.

edited May 23 '17 at 12:34

Community

1
1

answered Dec 26 '13 at 21:54

Gray

7,050
2
29
52

thanks for answering, but i cannot use a batch file.. I need to use a single command.. – Matias Elorriaga Dec 26 '13 at 21:57
@MatiasElorriaga You can run for loop directly from CMD - there is just 1 '%' sign, e.g.::::::::::::::::::::::::::::::: `for %i in (*.css) do ( ren "%~i" "_%~i.scss" )` => rename all files with .css extension to "_ORIGINALFILENAME.scss" – jave.web Aug 09 '17 at 13:47
give me access denied – Cristián Vargas Acevedo Jun 17 '23 at 05:24
@CristiánVargasAcevedo sounds like a file permission error to me. – Gray Jul 08 '23 at 01:32

score 12 · Answer 3 · answered Jun 16 '16 at 07:51

12

Simple as:

set filename=qwe qwe qwe asd.exe
set filename=%filename: =_%

answered Jun 16 '16 at 07:51

n8b

129
1
2

2

how does that rename files? – Stephan Jun 16 '16 at 08:09
1

`set filename=qwe qwe qwe asd.exe`, `set filename2=%filename: =_%`, `ren "filename" "filename2"` – kokbira Apr 25 '17 at 14:15
works only as long as the original file name is "qwe qwe qwe asc.exe" – Peter Feb 03 '19 at 12:16

score 8 · Answer 4 · answered Nov 14 '14 at 23:46

8

Using forfiles:

forfiles /m *.exe /C "cmd /e:on /v:on /c set \"Phile=@file\" & if @ISDIR==FALSE ren @file !Phile: =_!"

Add /s after forfiles to recurse through subfolders.

answered Nov 14 '14 at 23:46

Jimadine

998
13
26

2

In case you want to change spaces to dashes or dashes to underscores the bit that controls the "turn this into that" logic is `Phile: =_!`. Whatever comes before the `=` is what will be replaced. The thing that goes after the `=` is what it will be replaced with. – Daniel Tonon Dec 01 '16 at 01:11

score 4 · Answer 5 · answered Mar 27 '18 at 17:35

4

Based on @Gray answer, I have extending it to replace filenames recursively in all subdirectories.

File 1: replace.bat

setlocal enabledelayedexpansion

set "pattern= "
set "replace=_"

for %%I in (*.ext) do (
    set "file=%%~I"
    ren "%%I" "!file:%pattern%=%replace%!"
)

File 2: recursive.bat

for /d /r . %%D in (*) do (
    copy replace.bat "%%D\replace.bat"
    cd "%%D"
    replace.bat
    del replace.bat
    cd..
)

Files

replace.bat contains script to replace space with underscore
recursive.bat contains script to do recursion in all subdirectories

How to use?

Save both replace.bat and recursive.bat in same directory.
Replace .ext with desired file extension to match (like .mp4) in replace.bat.
Double click (run) ONLY recursive.bat file.

answered Mar 27 '18 at 17:35

Hamza Rashid

1,329
15
22

this only works if I manually copy the replace.bat in all subfolders. Which is quite a pain. What should i add to manually copy the replace.bat to all subfolders? – guthik Jul 26 '18 at 14:33
please follow **how to use** section – Hamza Rashid Aug 01 '18 at 11:05
Mhm, I see so you assume theres only one subdirectory. In my case the directory contains many subdirectories each with a subdirectory with a file I want to rename. Do I still have to copy both the replace and recursive bat files to each of them? – guthik Aug 01 '18 at 11:17
Place `replace.bat` and `recursive.bat` in parent directory, it'll work on all child directories. – Hamza Rashid Aug 02 '18 at 13:45

score 1 · Answer 6 · answered Aug 19 '15 at 12:19

1

set data=%date:~6,4%%date:~3,2%%date:~0,2%_%time:~0,2%%time:~3,2%%time:~6,2% set data=%data: =0%

answered Aug 19 '15 at 12:19

ricarela

30
3

Loved this! Exactly what I needed to get spaces out of string. – C J Jul 01 '22 at 13:18

score 1 · Answer 7 · edited Sep 19 '18 at 11:14

1

Save the following 2 commands in a .bat file. It will replace " " with "_" in all files and folders, recursively, starting from the folder where the file is stored.

forfiles /s /m *.* /C "cmd /e:on /v:on /c set \"Phile=@file\" & if @ISDIR==FALSE ren @file !Phile: =_!"
forfiles /s /C "cmd /e:on /v:on /c set \"Phile=@file\" & if @ISDIR==TRUE ren @file !Phile: =_!"

Note: First line is doing this for files, and second one is doing this for folders. Each line can be used separately.

edited Sep 19 '18 at 11:14

Adrien Blanquer

2,041
1
19
31

answered Sep 19 '18 at 09:35

Alex

11
1

This is the only answer that I tried that worked for me; Works on files AND directories; Only needs 1 file, not 2. Not sure why it had zero upvotes or comments...? – Realto619 May 15 '22 at 17:41

score 0 · Answer 8 · answered Apr 02 '19 at 21:35

Minor tweak to Hamza Rashid's answer. Specifically his recursive.bat script.

recursive.bat

set orig=%cd%

for /d /r . %%D in (*) do (
    copy replace.bat "%%D\replace.bat"
    cd "%%D"
    replace.bat
    del replace.bat
    cd %orig%
)

replace.bat stays the same and the instructions stay the same.

How to replace all spaces by underscores in all file names of a folder?

8 Answers8

Linked

Related