Excel VBA Macro - Copy and insert copied cells

Question

I can't seem to make to this work. I keep getting stuck on

    Rows(rng 5).Select

What I am trying to do is copy the row of the active cell and inserting the copied cell in a row that is 5 rows below the active cell.

Sub CopyConcatenate()


    Dim ws As Worksheet
    Dim rng As Range

    Set rng = ActiveCell.Rows

    rng.Select
    Selection.Copy
    Rows(rng 5).Select
    Selection.Insert Shift:=xlDown

End Sub

What are you trying to do in `Rows(rng 5).Select` ? This should through an error cause the syntax is incorrect. — Pankaj Jaju, Jan 30 '14 at 11:52
I'm trying to select the row that is 5 rows below the one with the active cell. — NoNo, Jan 30 '14 at 11:55

score 20 · Accepted Answer · edited Jan 07 '22 at 08:22

20

Try this

Sub CopyConcatenate()
    Dim ws As Worksheet
    Dim rng As Range
    
    '~~> Set this to the relevant worksheet
    Set ws = ThisWorkbook.Sheets("Sheet1")
    
    With ws
        '~~> Set your range
        Set rng = .Rows(ActiveCell.Row)
        
        '~~> Copy the range
        rng.Copy
        
        '~~> Insert the range
        rng.Offset(5).Insert Shift:=xlDown
        
        '~~> Clear the clipboard. More importantly remove the
        '~~> ant like borders
        Application.CutCopyMode = False
    End With
End Sub

edited Jan 07 '22 at 08:22

Nimantha

6,405
6
28
69

answered Jan 30 '14 at 11:52

Siddharth Rout

147,039
17
206
250

1

[INTERESTING READ](http://stackoverflow.com/questions/10714251/excel-macro-avoiding-using-select) – Siddharth Rout Jan 30 '14 at 12:00

Excel VBA Macro - Copy and insert copied cells

1 Answers1

Linked