2

I have an xml document following this overall pattern:

<A b="c" d="e" f="g" h="i">
  <!-- plenty of children -->
</A>

I would like to copy the A node with only some of it's attributes:

<A b="c" f="g">
  <!-- some of the children -->
</A>

Other answers here have come close to solving my challenge but have not quite been enough:

  • This answer gave me a solution that would work but would be very long: https://stackoverflow.com/a/672962/145978
    • so I could go with <xsl:copy-of select="@*[(name()!='d') or (name()!='h']"/> but my actual attribute list is very long.
    • I did try finding a 'is-a-member-of-this-list'-type function but got lost rather quickly.
  • This answer seemed to discuss a Whitelist but I am apparently not smart enough to be able to apply it to attribute selection: https://stackoverflow.com/a/5790798/145978

Please help

Community
  • 1
  • 1
LRE
  • 956
  • 1
  • 10
  • 15

3 Answers3

3

The whitelist solution that you linked uses an embedded document containing the list of elements that should be preserved. You can have a similar one for your attributes:

<myns:whitelist>
    <keep>b</keep>
    <keep>f</keep>
</myns:whitelist>

It can be loaded and parsed using the document('') function, and you can store it in a variable to make it easier to refer to it:

<xsl:variable name="keep" select="document('')/*/myns:whitelist/keep"/>

Now the $keep variable contains the names of all the attributes in the list. The asterisk represents the <xsl:stylesheet> element, since the argument passed to document() is an empty string, which causes it to load from the current document.

Then you can test if the names of arbitrary atrributes match any one that is in the $keep node-set:

@*[name()=$keep]

The others you copy using an identity transformation.

Here is a full stylesheet for the example you provided:

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0" xmlns:myns="myns">

    <xsl:output indent="yes"/>
    <xsl:strip-space elements="*"/>

    <myns:whitelist>
        <keep>b</keep>
        <keep>f</keep>
    </myns:whitelist>

    <xsl:variable name="keep" select="document('')/*/myns:whitelist/keep"/>

    <xsl:template match="A">
        <xsl:copy>
            <xsl:apply-templates select="node()|@*[name()=$keep]"/>
        </xsl:copy>
    </xsl:template>

    <xsl:template match="@*|node()">
        <xsl:copy>
            <xsl:apply-templates select="@*|node()"/>
        </xsl:copy>
    </xsl:template>

</xsl:stylesheet>
helderdarocha
  • 23,209
  • 4
  • 50
  • 65
  • thankyou so much - it works like a charm. The key for me was the variable declaration. I didn't know that bit about the `document()` function – LRE May 23 '14 at 04:40
2

Generally, if you want to drop something from the input, write an empty template for what you want to remove:

<!-- drop every attribute of <A> ... -->
<xsl:template match="A/@*" />

and another, non-empty template for what you want to keep:

<!-- ... except @b and @f -->
<xsl:template match="A/@b | A/@f">
  <xsl:copy-of select="." />
</xsl:template>

and then simply apply templates normally:

<xsl:template match="A">
  <xsl:copy>
    <xsl:apply-templates select="@*" />
    <!-- other output -->
  </xsl:copy>
</xsl:template>

That's all, this does the right thing already.

Hint: If you have an identity template in place in your stylesheet and no other changes to <A> are necessary then you don't even need that third template.

Tomalak
  • 332,285
  • 67
  • 532
  • 628
  • I'm just wondering about the viability of this approach when the whitelist is quite long ? – LRE May 23 '14 at 06:16
  • @LRE Define "viability". A long match expression containing, say, 50 attributes will neither confuse your XSLT engine nor make the whole thing slow. (I'd even argue that this is the fastest approach of all shown alternatives, even for very long white-lists.) – Tomalak May 23 '14 at 06:56
  • 1
    Certainly in Saxon matching names in a template rule like this will perform better than using string comparisons, because tests for element and attribute names are reduced to integer comparisons and template rules specifying explicit names are found by hash table lookup. – Michael Kay May 23 '14 at 10:45
  • fair point, Tomalak. When I said "viability", I was thinking in terms of typing out a really long set of comparisons vs the whitelisting approach from helderdarocha - which to my eyes would be more readable at least. – LRE May 23 '14 at 22:59
1

If you're using XSLT 2.0, you can use a sequence. If you put it in an xsl:param instead of an xsl:variable, you can define the whitelist at runtime (if you want).

Example:

XSLT 2.0

<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output indent="yes"/>
    <xsl:strip-space elements="*"/>

    <xsl:param name="whitelist" select="('b','f')"/>

    <xsl:template match="@*|node()">
        <xsl:copy>
            <xsl:apply-templates select="@*|node()"/>
        </xsl:copy>
    </xsl:template>

    <xsl:template match="A">
        <xsl:copy>
            <xsl:apply-templates select="@*[name()=$whitelist]|node()"/>
        </xsl:copy>        
    </xsl:template>

</xsl:stylesheet>
Daniel Haley
  • 51,389
  • 6
  • 69
  • 95