67

I have this arduino sketch,

char temperature[10];
float temp = 10.55;
sprintf(temperature,"%f F", temp);
Serial.println(temperature);

temperature prints out as

? F

Any thoughts on how to format this float? I need it to be a char string.

Dinal24
  • 3,162
  • 2
  • 18
  • 32
Mistergreen
  • 1,052
  • 1
  • 8
  • 16

4 Answers4

145

Due to some performance reasons %f is not included in the Arduino's implementation of sprintf(). A better option would be to use dtostrf() - you convert the floating point value to a C-style string, Method signature looks like:

char *dtostrf(double val, signed char width, unsigned char prec, char *s)

Use this method to convert it to a C-Style string and then use sprintf, eg:

char str_temp[6];

/* 4 is mininum width, 2 is precision; float value is copied onto str_temp*/
dtostrf(temp, 4, 2, str_temp);
sprintf(temperature,"%s F", str_temp);

You can change the minimum width and precision to match the float you are converting.

Dinal24
  • 3,162
  • 2
  • 18
  • 32
9

As has been stated before Float support is not included in sprintf on Arduino.

String class

Arduino has its own String class.

String value = String(3.14);

then,

char *result = value.c_str();

String class reference, link above

Constructs an instance of the String class. There are multiple versions that construct Strings from different data types (i.e. format them as sequences of characters), including:

  • a constant string of characters, in double quotes (i.e. a char array)
  • a single constant character, in single quotes
  • another instance of the String object
  • a constant integer or long integer
  • a constant integer or long integer, using a specified base
  • an integer or long integer variable
  • an integer or long integer variable, using a specified base
  • a float or double, using a specified decimal places
Tommylee2k
  • 2,683
  • 1
  • 9
  • 22
Cameron Lowell Palmer
  • 21,528
  • 7
  • 125
  • 126
  • 3
    Important notice to the pointer above: "When you modify the String object, or when it is destroyed, any pointer previously returned by c_str() becomes invalid and should not be used any longer." – JrBenito Aug 31 '17 at 03:54
  • 1
    I would say, obviously, but yes, that is an excellent point for people new to Arduino programming. – Cameron Lowell Palmer Aug 31 '17 at 08:05
  • Arduino's String class does not have a method that accepts float or double. This only works because it converts it to an integer. – Cerin Mar 29 '18 at 01:19
  • 1
    @CameronLowellPalmer You're right, my mistake. The most recent Arduino release does include String support for double and float. I'm using an older release included with Ubuntu that pre-dates this, and throws a compiler error when I try to pass a float to String(). – Cerin Mar 31 '18 at 18:03
  • Caution: just a tedious yet important note about String class for newbies: it dynamically allocates/deallocates heap memory, because of this it is a great generator of "heap-fragmentation" in the long run. Try to keep its use limited preferring C-style strings. [More about Arduino memory caveats](https://learn.adafruit.com/memories-of-an-arduino/you-know-you-have-a-memory-problem-when-dot-dot-dot) – Niki Romagnoli Apr 12 '19 at 17:31
  • 3
    It even takes second parameter as precision, `String(3.1434, 4)` – Orkhan Alikhanov Aug 17 '19 at 12:35
2

I've struggled for a few hours on getting this right, but I did finally. And this uses modern Espressif C++ provided by Platformio, and my target MCU is an ESP32.

I wanted to display a prefix label, the float/int value, then the unit, all inline.

I can't relay on seperate Serial.print() statements, as I am using an OLED display.

Here's my code example:

  int strLenLight = sizeof("Light ADC: 0000");
  int strLenTemp = sizeof("Temp: 000.0 °C");
  int strLenHumd = sizeof("Humd: 00.0 %");

  char displayLight[strLenLight] = "Light ADC: ";
  char displayTemp[strLenTemp] = "Temp: ";
  char displayHumd[strLenHumd] = "Humd: ";

  snprintf(strchr(displayLight, '\0'), sizeof(displayLight), "%d", light_value);
  snprintf(strchr(displayTemp, '\0'), sizeof(displayTemp), "%.1f °C", temperature); 
  snprintf(strchr(displayHumd, '\0'), sizeof(displayHumd), "%.1f %%", humidity); 

  Serial.println(displayLight);
  Serial.println(displayTemp);
  Serial.println(displayHumd);

Which displays:

Light ADC: 1777
Temp: 25.4 °C
Humd: 55.0 %
Excalibur
  • 3,258
  • 2
  • 24
  • 32
0

dtostrf() is deprecated, and it doesn't exist on every board core platforms. On the other hand, sprintf() doesn't format floats on AVR platforms!

Gerhard
  • 6,850
  • 8
  • 51
  • 81
Helmut Wunder
  • 1
  • The `sprintf()` linked by default does not support `%f`, but you can link in a full version of `sprintf()` if required. – Gerhard Feb 18 '20 at 14:29