Matching on namespace during xsl transform

Question

I have a document of which the root element defines a namespace, when I write a xsl to transform I don't see any elements matched.

<xsl:stylesheet version="2.0"
            xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

    <xsl:template match="node()|@*">
      <xsl:copy>
        <xsl:apply-templates select="node()|@*"/>
      </xsl:copy>
    </xsl:template>

    <xsl:template match="//supplydetail/price"/>

</xsl:stylesheet>

The XML file looks like this:

<?xml version="1.0" encoding="iso-8859-1"?>
<ONIXmessage xmlns="http://www.editeur.org/onix/2.1/short">
  <header>
    <m173>2012086</m173>
    <m174>foobar</m174>
  </header>
  <product>
    <supplydetail>
        <j137>Foo Bar</j137>
        <j396>20</j396>
        <price>
            <j148>42</j148>
            <j151>5.99</j151>
            <j152>AUD</j152>
            <b251>AU</b251>
        </price>
    </supplydetail>
  </product>
</ONIXmessage>

What I see is that my supplydetail/price element is not matched at all even when it exists in the document at /ONIXmessage/product/supplydetail/price

I tried to specify the full path from root as well in the xsl and that din't work either. The output I get is a straight copy of the input, what I am expecting is that a copy of the input except the price element. I think the reason is the namespace declaration in ONIXmessage element of the input XML, but how do I specify that in the xsl.

Thanks

This question has been asked hundreds of times, and there are many good answers. To find one that suits your needs, search for _default namespace_ in the context of XSLT, e.g. http://stackoverflow.com/q/1344158/1987598. — Mathias Müller, Sep 02 '15 at 20:02
Mathias, thank you for your response, my problem was that I was not able to formulate the question in way that it returned the links you mentioned. — Vijay Kumar, Sep 04 '15 at 02:26

score 2 · Accepted Answer · edited May 23 '17 at 12:14

I agree with Matthias Müller that this question has been asked often, but I disagree that it is wrong to ask it again. You may have already tried to find the solution and failed to understand or apply what you found.

An excellent introductory-to-in-depth treatise of the subject can be found at Understanding XML Namespaces and Namespaces in XSLT, both by Evan Lenz. I can really recommend spending a moment of your time reading this if you want to do anything useful with XML and XSLT.

Bottom line is: declare the namespace in XSLT, typically at the top xsl:stylesheet element and use these namespaces in your XPath expressions:

<xsl:stylesheet version="2.0"
    xmlns:onix="http://www.editeur.org/onix/2.1/short"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

    <xsl:template match="node()|@*">
      <xsl:copy>
        <xsl:apply-templates select="node()|@*"/>
      </xsl:copy>
    </xsl:template>

    <xsl:template match="//onix:supplydetail/onix:price"/>

</xsl:stylesheet>

Since you are using XSLT 2.0, you can suffice by using xpath-default-namespace, which sets the namespace used for unprefixed node-tests in XPath expressions and patterns:

<xsl:stylesheet version="2.0"
    xpath-default-namespace="http://www.editeur.org/onix/2.1/short"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

To get the same namespace to be used for literal result elements, either prefix those names with a declared namespace, or set the default namespace to point to your namespace of choice (in your current code, there are no literal result elements).

If you do not know the actual namespace beforehand, but you do know the local name, use match patterns like *:supplydetail, but this has the risk to also match the same name in another namespace; if you can avoid it, you should.

Matching on namespace during xsl transform

1 Answers1