How to Get which Radio Button is Checked in a Groupbox then insert it to a database

Question

I want to insert a record in a database with two groupbox. groupbox1 (has Male and female radio buttons) and groupbox2 ( has New students and old students radio buttons)

In this case there will be four possible input the needs to be check

1. Male and old students
2. Male and new students
3. Female and old students
4. Female and New students

Normally I will check each radio button individually just like this

   If rbtMale.Checked And rbtOld.Checked Then
            Dim OldStudent = rbtOld.Text.ToString
            Dim Male = rbtMale.Text.ToString
            Using cmd As New SqlClient.SqlCommand("dbo.uspInsert", cn)
                cmd.CommandType = CommandType.StoredProcedure
                cmd.Parameters.Add(New SqlParameter("@StudPic", SqlDbType.Image))
                If (Not String.IsNullOrEmpty(Me.Name) AndAlso System.IO.File.Exists(a.FileName)) Then
                    cmd.Parameters("@StudPic").Value = System.IO.File.ReadAllBytes(a.FileName)
                    cmd.Parameters.Add("@SurName", SqlDbType.VarChar, 100).Value = txtStudLN.Text
                    cmd.Parameters.Add("@FirstName", SqlDbType.VarChar, 100).Value = txtStudFN.Text
                    cmd.Parameters.Add("@Gender", SqlDbType.VarChar, 100).Value = Male
                    cmd.Parameters.Add("@Status", SqlDbType.VarChar, 100).Value = OldStudent
                    cmd.ExecuteNonQuery()
                    MsgBox("Save Record New record Successfully")
               End If
            End Using
        End If

But I think there is smart way to check which radio button being checked in a groupbox and insert it in a database. Below are some codes that gives me idea about this but the problem is that i do not know how to pass the value in a groupbox then insert this in my db. Any help would be very much appreciated. Thanks

For Each Ctrl In GroupBox1.Controls
    If Ctrl.checked Then MsgBox(Ctrl.name)
Next

Answer 1

You're nearly there in the snippet at the bottom of your question. This function takes a groupbox as the parameter and returns the RadioButton that is checked

Private Function GetGroupBoxCheckedButton(grpb As GroupBox) as RadioButton
    For Each ctrl As RadioButton In grpb.Controls
        If ctrl.Checked Then Return ctrl
    Next
End Function

You'll get a compiler warning about the function not returning a result on all code paths, but this shouldn't matter with RadioButtons - assuming that you have more than one radiobutton in the groupbox - in theory.

Alternatively you could use this instead. It wont generate a compiler warning, but is less readable:-

Private Function GetGroupBoxCheckedButton(grpb As GroupBox) As RadioButton
    Dim rButton As RadioButton = grpb.Controls.OfType(Of RadioButton).Where(Function(r) r.Checked = True).FirstOrDefault()
    Return rButton
End Function

To get the text value just use something like

Dim value As String  = GetGroupBoxCheckedButton(GroupBox1).Text 

I'm guessing that all you want to do here is to add the RadioButton text to your database and rather than write the above code multiple times, you just want to do it the once. All you'll need to is remove the If and End If statements and ammend the first bit of your code to read ..

        Dim Status As String= GetGroupBoxCheckedButton(GroupBox1).Text
        Dim Gender As String= GetGroupBoxCheckedButton(GroupBox2).Text

Incidentally, you don't need .ToString at the end of these lines as the .Text Property returns a string and no conversion to a string is needed

And finally change variables further down your code to match.

        cmd.Parameters.Add("@Gender", SqlDbType.VarChar, 100).Value = Gender
        cmd.Parameters.Add("@Status", SqlDbType.VarChar, 100).Value = Status