Variable value not showing in Win Batch

Question

I am writing a batch to automate the installation of a a number of settings, INI files and APKs on a multitude of devices. I am getting errors in the batch due to the variables in showing NULL.

I have checked that the config.ini and ADBCommands.ini and adb+.bat are in the correct location.

Can you help?

::Global
@echo off
cd C:\

::INI Locations
set mypath=%~dp0
set config=%mypath%config.ini
set Commands=%mypath%ADBCommands.ini
set multi=%mypath%adb+.bat
@pause

::Set Varialbes
@for /f "tokens=1,2 delims==" %%a in (%config%) do (
if %%a==Build set Build=%%b
if %%a==Version set Version=%%b
if %%a==Creator set Creator=%%b
if %%a==DateModified set DateModified=%%b
if %%a==ScreenTimeout set ScreenTimeout=%%b
if %%a==UnknownSources set UnknownSources=%%b
if %%a==ScreenBrightness set ScreenBrightness=%%b
)

@for /f "tokens=1,2 delims==" %%d in (%Commands%) do (
if %%d==ScreenTimeoutCommand set ScreenTimeoutCommand=%%e
if %%d==UnknownSourcesCommand set UnknownSourcesCommand=%%e
if %%d==ScreenBrightnessCommand set ScreenBrightnessCommand=%%e
if %%d==OpenSOTICommand set OpenSOTICommand=%%e
)

::Build information
cls
@echo.
@echo.
@echo      BUILD:              %Build%
@echo      VERSION:            %Version%
@echo      BUILD CREATOR:      %Creator%
@echo      LAST UPDATED:       %DateModified%
@echo.
@echo.
@pause

Contents the ini files config.ini

Build=XCover 3
Version=1.0.0
Creator=James B
DateModified=20/02/2017
ScreenTimeout=300000
UnknownSources=1
ScreenBrightness=225

Contents the ini files ADBCommands.ini

ScreenTimeoutCommand=shell settings put system screen_off_timeout
UnknownSourcesCommand=shell settings put system install_non_market_apps
OpenSOTICommand=shell am start -n net.soti.mobicontrol.elm.samsung/net.soti.mobicontrol.startup.SplashActivity

You do not need to set your FOR meta variables to environmental variables to use them. Just use the FOR meta variables directly. Also, you already have echo off, so you do not need to precede all your commands with the @. Also, I am not understanding why you are using: `cmd.exe /c` to execute your FOR commands. — Squashman, Feb 20 '17 at 16:26
Regardless of the above, this is a lot of code to troubleshoot and none of us will be able to replicate your configuration. You will have to tell us the exact lines of code you are having problems with. — Squashman, Feb 20 '17 at 16:29
`%Build%` `%Version%` `%Creator%` and `%DateModified%` variables are showing nothing. — beecho01, Feb 20 '17 at 16:37
@Squashman i put in the `cmd.exe /c` as the ADB+.bat was closing the batch file before completion — beecho01, Feb 20 '17 at 16:39
Possible duplicate of [Windows Batch Variables Won't Set](http://stackoverflow.com/questions/9681863/windows-batch-variables-wont-set) — SomethingDark, Feb 20 '17 at 16:51
Without seeing the contents of the config and commands files, it would be difficult to troubleshoot what the two FOR commands are doing to those files. — Squashman, Feb 20 '17 at 16:54

score 1 · Accepted Answer · answered Feb 20 '17 at 17:15

1

Because your path has spaces you need to enclose the path with quotes. But when you do this, you need to tell the FOR /F command that you are still parsing a file and not a variable. So you need to use the USEBACKQ option.

@for /f "usebackq tokens=1,2 delims==" %%a in ("%config%") do (

AND

@for /f "usebackq tokens=1,2 delims==" %%d in ("%Commands%") do (

answered Feb 20 '17 at 17:15

Squashman

13,649
5
27
36

Worked perfectly! Thanks very much – beecho01 Feb 20 '17 at 17:24

Variable value not showing in Win Batch

1 Answers1