Excel VBA deleting rows in a for loop misses rows

Question

I have a subroutine that deletes rows in a range containing around 1000 rows. Rows are deleted on a critera. The code below works.

However, when I run the macro I usually have to run it 4 times before all rows containing the removal criteria are removed.

I guess this is because the for loop misses its index when a row suddenly dissapears when deleting a row.

My first code looks like this.

Set StatusRange = Range("B2", Range("B2").End(xlDown))

For Each StatusCell In StatusRange
    If StatusCell = "FG" Then
        StatusCell.EntireRow.Delete
    ElseIf StatusCell = "QC" Then
        StatusCell.EntireRow.Delete
    ElseIf StatusCell = "CS" Then
        StatusCell.EntireRow.Delete
    Else
    End If
Next StatusCell

When I try to update the range each loop, it still doesn't work.

Set StatusRange = Range("B2", Range("B2").End(xlDown))

For Each StatusCell In StatusRange
    If StatusCell = "FG" Then
        StatusCell.EntireRow.Delete
    ElseIf StatusCell = "QC" Then
        StatusCell.EntireRow.Delete
    ElseIf StatusCell = "CS" Then
        StatusCell.EntireRow.Delete
    Else
    End If
                
    Set StatusRange = Range("B2", Range("B2").End(xlDown))
Next StatusCell

Is there anyone who know a sloution to this?

Work from teh bottom up. If you delete a row, everything moves up and yuou skip that row on teh next iteration. — , Apr 17 '17 at 15:11
This is almost certainly a duplicate question and I'll mark it as such when I find the suitable duplicate. Whenever you delete items from a collection, you *must* delete from `Rows.Count to 1 Step -1` otherwise you will skip rows. — David Zemens, Apr 17 '17 at 15:12
Go ahead and dupe this @DavidZemens - I've added some value by showing the Case statement for multiple comparisons but this is still a dupe. — , Apr 17 '17 at 15:16
Here's a good explanation: http://stackoverflow.com/questions/23689196/understanding-vba-code-using-to-and-step/23697899#23697899 — David Zemens, Apr 17 '17 at 15:17
And another with an accepted answer which actually appears to be VB.NET code but the principle is the same: http://stackoverflow.com/questions/10315120/visual-basic-excel-macro-to-delete-row/10316029#10316029 — David Zemens, Apr 17 '17 at 15:17
btw, re-evaluating the range to iterate through in a `For ... Next` has no effect. It is considered 'static' upon entering the For ... Next and cannot be changed. While you *can* change the iteration point (in your code as `StatusCell`), it is not recommended. — , Apr 17 '17 at 15:31

score 16 · Accepted Answer · 2017-04-17T15:24:34.403

16

Work from the bottom up. If you delete a row, everything moves up and you skip that row on the next iteration.

Here is the 'guts' of the code to work up from the bottom.

With Worksheets("Sheet1")
    For rw = .Cells(.Rows.Count, "B").End(xlUp).Row To 2 Step -1
        Select Case UCase(.Cells(rw, "B").Value2)
            Case "FG", "QC", "CS"
                .Rows(rw).EntireRow.Delete
        End Select
    Next rw
End With

edited Apr 17 '17 at 15:24

answered Apr 17 '17 at 15:16

I was writing literal same answer (complete with `Case` statement) haha :D – David Zemens Apr 17 '17 at 15:20
1

Damn, I was just finished typing and posting almost the exact same code ;) – Shai Rado Apr 17 '17 at 15:21

score 4 · Answer 2 · answered Apr 17 '17 at 15:20

Since there's no Reverse loop for For Each you need to use a slightly different approach.

Also, your code with multiple Ifs and OR is "screaming for the use of Select Case.

Dim StatusRange As Range
Dim i As Long

Set StatusRange = Range("B2", Range("B2").End(xlDown))

' loop backward when deleting Ranges, Rows, Cells
For i = StatusRange.Rows.Count To 1 Step -1
    Select Case StatusRange(i, 1).Value
        Case "FG", "QC", "CS"
            StatusRange(i, 1).EntireRow.Delete
        Case Else ' for the future if you need it

    End Select
Next i

Victor Porée · Answer 3 · 2020-02-11T15:37:28.773

4

Wait til the For Each loops ends before deleting the rows:

Option Explicit

Sub mySub()

    Dim myRange As Range
    Set myRange = ActiveSheet.UsedRange

    Dim myCell As Range
    Dim myTrash As Range

    For Each myCell In myRange
        Select Case myCell.Value
            Case "my value"
                If myTrash Is Nothing _
                    Then
                        Set myTrash = myCell.EntireRow
                    Else
                        Set myTrash = Union(myTrash, myCell.EntireRow)
                End If
        End Select
    Next

    If Not myTrash Is Nothing Then myTrash.Delete

End Sub

edited Feb 11 '20 at 15:37

answered Jan 16 '20 at 03:42

Victor Porée

51
3

For me this was actually the best solution. I just added `If rngToBeDeleted Is Nothing Then Set rngToBeDeleted = xlRow.EntireRow` before the Union() to avoid an error when the range is not set initially. – snibbo Jan 29 '20 at 07:15

Machiel · Answer 4 · 2021-10-30T11:01:36.840

start_over: s = 0  
    for each cell  
        if cell = "FG" then   
           s = 1            'Marked to start over if ifstmt was true
           [other code]
        end if  
    next cell  
   If s = 1 Then GoTo start_over

'your code:

Set StatusRange = Range("B2", Range("B2").End(xlDown))  
    start_over: s = 0  
    For Each StatusCell In StatusRange  
        If StatusCell = "FG" or StatusCell = "QC" or StatusCell = "CS" Then StatusCell.EntireRow.Delete: s=1  
    Next StatusCell  
   If s = 1 Then GoTo start_over

Excel VBA deleting rows in a for loop misses rows

4 Answers4

Linked

Related