Batch file to copy files from 1 day before and no more

Question

imagine that I have 2 folders:

• C:\FolderData (will be incremented daily with new files)
• C:\FolderTemp (Needs to have only files from the day before executing, excluding hours/timestamp)

The FolderData will receive filenames that if not for date would be equals, as in:

1. SYS_PURCHASES_20170612.xls
2. SYS_PURCHASES_20170613.xls
3. SYS_PURCHASES_20170614.xls

If I run the .bat file today I need that only the SYS_PURCHASES_20170613.xls be copied over to FolderTemp.

I tried using robocopy but apparently it can't receive the same value for minage and maxage

robocopy "C:\FolderData" "C:\FolderTemp" /minage:1 /maxage:1

Also, if I try:

robocopy "C:\FolderData" "C:\FolderTemp" /minage:1 /maxage:2

It will bring both SYS_PURCHASES_20170612.xls and SYS_PURCHASES_20170613.xls, which is not what I need.

Other than that, I tried using forfiles but also with no avail.

forfiles /p C:\FolderData /D -1 /C "/C /copy /y @file C:\FolderTemp"

or even

forfiles /p C:\FolderData /D -1 /C "/C /copy /y C:\FolderData\@file C:\FolderTemp"

And other variables but it returns something along the line "the system can't return the specified file" times the number of files in the folder.

Note that there are other processes involved bellow that should be ignored, It's just that I can't figure out how to do the step above.

All steps my batch filed needs to do:

1. Copy from folder1 files from 1 day prior to folder2 (what I need help)
2. Remove last 9 digits from all files from folder2 (will remove the date, used the loop on this solution) so the file will be SYS_PURCHASES.xls
3. Move and replacing the files from folder2 to folder3 (using a simple move /y)

Answer 1

Since you want to touch the files from yesterday only, I would use forfiles, because this command only regards the date but not the time, when specifying the /D option. robocopy instead also regards the time, which is probably not what you want.

This is a possible way:

@echo off
setlocal EnableExtensions DisableDelayedExpansion

rem // Define constants here:
set "_SOURCE=C:\FolderData"
set "_TARGET=C:\FolderTemp"
set "_MASK=?*_????????.*"
set /A "_DAYS_AGO=1"

rem // Check given age and calculate interim value `PREV` needed for `forfiles`:
(if %_DAYS_AGO% LSS 0 set "_DAYS_AGO=0") & set /A "PREV=_DAYS_AGO+1"
rem // Let `forfiles` output the filtered files and capture them by `for /F`:
for /F "delims= eol=|" %%F in ('
    rem/ Use two nested `forfiles` loops to filter for files of specified day: ^
        ^& forfiles /P "%_SOURCE%" /M "%_MASK%" /D -%_DAYS_AGO% ^
        /C "cmd /C if @isdir==FALSE > nul 2>&1 forfiles /M @file /D -%PREV% || echo @file"
') do (
    rem // Store current file name and extension:
    set "FILE=%%~nF" & set "FEXT=%%~xF"
    setlocal EnableDelayedExpansion
    rem // Copy the file and remove the last 9 characters from its name:
    > nul copy /Y "!_SOURCE!\!FILE!!FEXT!" "!_TARGET!\!FILE:~,-9!!FEXT!"
    endlocal
)

endlocal
exit /B