Batch copy files comparing date in filename with today date minus X days

Question

Disclamer: Previously I needed to compare the date from "last modified" but 5 minutes ago I got a new requirement that I need to compare with the date on the filename as I explain myself bellow.

Imagine that I have 2 folders:

• C:\FolderData (will be incremented daily with new files)
• C:\FolderTemp (Needs to have only files from the day before executing, excluding hours/timestamp)

The FolderData will receive filenames that if not for date would be equals, as in:

1. SYS_PURCHASES_20170617.xls
2. SYS_PURCHASES_20170618.xls
3. SYS_PURCHASES_20170619.xls

If I run the .bat file today I need that only the SYS_PURCHASES_20170618.xls be copied over to FolderTemp. That have to be accomplished by getting the last 8 characters from the filename (20170618) and checking if it matches to TODAYDATE - 1.

Is this possible with batch-files and if so, how?

Also accepting answers on Windows PowerShell(6.1) if it also does these steps after:

1. Copy all files from folder1 to folder2 when the date in the filenames = currentdate - 1;
2. Remove last 9 digits from all files from folder2 (will remove the date and undescore "_YYYYMMDD") so the file will be SYS_PURCHASES.xls (need to consider every file extension, as there will be .xls, .xlsx and .txt);
3. Move and replacing the files from folder2 to folder3 (using a simple move /y) - I believe it's possible to do this while doing step 2, no need for a third folder.

Answer 1

As long as the script isn't run on the first of March in a leap year, all files in FolderData with the last digits corresponding to "yesterday" will be

• Copied to FolderTemp while being stripped from the last 9 digits of the file name
• Moved to Folder3 while being stripped from the last 9 digits of the file name

My system uses the DDMMYYYY format. Swap the values of the first two variables to set it to MMDDYYYY.

setlocal enabledelayedexpansion


set day=%date:~,2%
set month=%date:~3,2%


set year=%date:~-4%
echo.%day%|findstr /r /b "0">nul&&set day=%day:~1%
echo.%month%|findstr /r /b "0">nul&&set month=%month:~1%
set /a day-=5
if %day% lss 1 (
    set /a day+=30
    set /a month-=1
    if !month!==2 (set /a day-=2
                   set /a leap=year%%4
                   if !leap!==0 set day+=1
    )
    for /l %%# in (1 2 7) do if %month%==%%# set /a day+=1
    for %%# in (8 10 12) do if %month%==%%# set /a day+=1
    if !month!==0 (
        set month=12
        set /a year-=1
    )
)
set day=0%day%
set month=0%month%

for %%# in (C:\FolderData\*) do (
    set name=%%~n#
    if "!name:~-8!"=="%year%%month:~-2%%day:~-2%" (
        copy "%%#" "C:\FolderTemp\!name:~,-9!%%~x#"
    )
)

Please tell me if I misunderstood something.

EDIT: Revised the script to account for going back mutliple days.

Answer 2

With the following powershell script folder2 isn't necessary, you didn't name folder3 - so adjust to your environment.

$Folder1 = "C:\Test\2017\06\20"
$Folder3 = "C:\Test\2017\06\20\Destination"

$YesterDay = (Get-Date).AddDays(-1).ToString('yyyyMMdd')

Get-ChildItem -Path $Folder1 -Filter "SYS_PURCHASES_$YesterDay.*"|Where{ !$_.PSisContainer}|
  Copy-Item -Destination {Join-Path $Folder3 (($($_.BaseName) -replace '_\d{8}$')+$_.Extension)} -whatif

Original output of above script only line breaks inserted

PS C:\test\2017\06\20> ls
    Directory: C:\test\2017\06\20

Mode                LastWriteTime         Length Name
----                -------------         ------ ----
d-----       06/20/2017     18:13                Destination
-a----       06/20/2017     18:01           1044 SO_44639321.ps1
-a----       06/20/2017     00:56             24 SYS_PURCHASES_20170617.xls
-a----       06/20/2017     00:56             24 SYS_PURCHASES_20170618.xls
-a----       06/20/2017     01:07             24 SYS_PURCHASES_20170619.txt
-a----       06/20/2017     00:56             24 SYS_PURCHASES_20170619.xls

PS C:\test\2017\06\20> .\SO_44639321.ps1
What if: Performing the operation "Copy File" on target 
"Item: C:\Test\2017\06\20\SYS_PURCHASES_20170619.txt Destination: C:\Test\2017\06\20\Destination\SYS_PURCHASES.txt".
What if: Performing the operation "Copy File" on target 
"Item: C:\Test\2017\06\20\SYS_PURCHASES_20170619.xls Destination: C:\Test\2017\06\20\Destination\SYS_PURCHASES.xls".
PS C:\test\2017\06\20> type .\SO_44639321.ps1

---

If the output looks right on your system remove the -whatif parameter at the end of the last line.

Answer 3

A combined Batch/PowerShell approach.

Powershell for the date calculation and pure batch for the rest

@Echo Off&Setlocal EnableDelayedExpansion
Set "Folder1=C:\Test\2017\06\20"
Set "Folder3=C:\Test\2017\06\20\Destination"

For /f "usebackq delims=" %%A in (
  `Powershell -NonI -Nop -Com "(Get-Date).AddDays(-1).ToString('yyyyMMdd')"`
) Do Set YesterDay=%%A

For /F "Delims=" %%A in (
  'Dir /B/A-D "%Folder1%\*_%YesterDay%.*" '
) Do (
  Set "File=%%~nA"
  Set "File=!File:_%YesterDay%=!"
  Echo Copy "%%~fA" "%Folder3%\!File!%%~xA"
)

Sample output

> SO_44639321.cmd
Copy "C:\Test\2017\06\20\SYS_PURCHASES_20170619.txt" "C:\Test\2017\06\20\Destination\SYS_PURCHASES.txt"
Copy "C:\Test\2017\06\20\SYS_PURCHASES_20170619.xls" "C:\Test\2017\06\20\Destination\SYS_PURCHASES.xls"

If the output looks OK remove the echo in front of copy.