How to capture active windows on desktop by vb.net?

Question

I'm using this code to capture desktop

Private Function cc() As Bitmap
    Dim s As Screen = Screen.PrimaryScreen
    Dim img As New Bitmap(s.Bounds.Width, s.Bounds.Height)
    Dim gr As Graphics = Graphics.FromImage(img)
    gr.CopyFromScreen(s.Bounds.Location, Point.Empty, s.Bounds.Size)
    Return img
End Function

Private Sub Button1_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button1.Click
    Try
        Me.PictureBox1.Image = cc()
    Catch ex As Exception
        MsgBox(ex.Message)
    End Try
End Sub

But now I want to capture only the active screen, how can I do that?

Regards,,,,,

lomed! How to Capture screenshot of active windows by vb.net not by c# — Max45, Jun 25 '17 at 10:28

score 3 · Answer 1 · answered Jun 25 '17 at 12:37

for copy active window from our application, Just check the position and size of the window and reduced the copying to this rectangle:

Public Sub ScreenCopy(Optional file As String = "d:\test.jpg")
    Dim bounds = Me.Bounds
    Using bitmap As New Bitmap(bounds.Width, bounds.Height)

        Using g = Graphics.FromImage(bitmap)
            g.CopyFromScreen(New Point(bounds.Left, bounds.Top), Point.Empty, bounds.Size)
        End Using

        bitmap.Save(file, ImageFormat.Jpeg)
        Process.Start(file) ' for test purposes
    End Using
End Sub

for copy current active window even is not part of our application you need use an api for detect his size and location.

for this use this class (credit: @KvanTTT: https://stackoverflow.com/a/9087955/1271037)

Class ScreenCapturer
    <DllImport("user32.dll")> _
    Private Shared Function GetForegroundWindow() As IntPtr
    End Function

    <DllImport("user32.dll")> _
    Private Shared Function GetWindowRect(hWnd As IntPtr, ByRef rect As Rect) As IntPtr
    End Function

    <StructLayout(LayoutKind.Sequential)> _
    Private Structure Rect
        Public Left As Integer
        Public Top As Integer
        Public Right As Integer
        Public Bottom As Integer
    End Structure

    Public Function Capture(Optional activeWindowOnly As Boolean = True) As Bitmap
        Dim bounds As Rectangle

        If Not activeWindowOnly Then
            bounds = Screen.GetBounds(Point.Empty)
            CursorPosition = Cursor.Position
        Else
            Dim foregroundWindowsHandle = GetForegroundWindow()
            Dim rect = New Rect()
            GetWindowRect(foregroundWindowsHandle, rect)
            bounds = New Rectangle(rect.Left, rect.Top, rect.Right - rect.Left, rect.Bottom - rect.Top)
            CursorPosition = New Point(Cursor.Position.X - rect.Left, Cursor.Position.Y - rect.Top)
        End If

        Dim result = New Bitmap(bounds.Width, bounds.Height)

        Using g = Graphics.FromImage(result)
            g.CopyFromScreen(New Point(bounds.Left, bounds.Top), Point.Empty, bounds.Size)
        End Using

        Return result
    End Function

    Public Property CursorPosition() As Point

End Class

how to use:

Public Sub ScreenCopy(Optional file As String = "d:\test.jpg")
    Dim sc = New ScreenCapturer()

    Using bitmap = sc.Capture()
        bitmap.Save(file, ImageFormat.Jpeg)
        Process.Start(file) ' for test purposes
    End Using
End Sub

Sorry but I can't figure it out – Max45 Jun 30 '17 at 04:31 — Max45, Jun 30 '17 at 04:31

score 0 · Answer 2 · answered Jul 15 '22 at 16:23

Only a small change in syntax for VB.net regarding the DLL import:

<DllImport("user32.dll", EntryPoint:="GetForegroundWindow")> Private Shared Function GetForegroundWindow() As IntPtr
 End Function

 <DllImport("user32.dll", EntryPoint:="GetWindowRect")> Private Shared Function GetWindowRect(hWnd As IntPtr, ByRef rect As Rect) As IntPtr
  End Function

How to capture active windows on desktop by vb.net?

2 Answers2