How to add events to dynamically created controls (buttons, listboxes) in Excel VBA userform

Question

I am trying to build a userform in real time. (in Excel VBA) Just to try-out, I started with 2 labels, a textbox, a combobox and a commandbutton. I list the code below + the resulting form.

My question is: How can I get events linked to the controls, specifically the combobox and commandbutton? Normally (with manually created forms), this would be done by the routines called: cmbTabel_change() and cmdExit_click(). But this doesn't seem to work, when they are dynamically created. Who can help me?

Code:

Private Sub UserForm_Initialize()
    Dim cCont As Control

    Call Add_Control(cCont, "Label", "lblDatabase", "Database", 30, 23, 60, 18)
    Call Add_Control(cCont, "Textbox", "txtDatabase", "Database", 110, 20, 60, 18)
    Call Add_Control(cCont, "Label", "lblTabel", "Tabel", 30, 47, 90, 18)
    Call Add_Control(cCont, "Combobox", "cmbTabel", "Tabel", 110, 44, 90, 18)
    Call Add_Control(cCont, "CommandButton", "cmdExit", "Afsluiten", 210, 140, 54, 18)
End Sub

Private Sub Add_Control(ctrl, ctp, cnm, cap, l, t, w, h)
    Set ctrl = Me.controls.Add("Forms." & ctp & ".1", cnm)
    With ctrl
        .Left = l
        .Top = t
        .Width = w
        .Height = h
    End With

    Select Case ctp
    Case "Combobox"
        controls(cnm).Clear
        For j = 1 To 5
            controls(cnm).AddItem "ListItem" & j
        Next j
        controls(cnm).ListIndex = 0
    Case "Label", "CommandButton"
        With controls(cnm)
            .Caption = cap
        End With
    Case "Textbox"
        controls(cnm).Text = cap
    End Select
End Sub

Resulting form:

Answer 1

You'll need to build a class to handle the events on the controls.

As an example create a new class module called clsMyEvents.
Add this code to the class:

Option Explicit

Public WithEvents MyCombo As MSForms.ComboBox
Public WithEvents MyButton As MSForms.CommandButton

Private Sub MyCombo_Change()
    MsgBox MyCombo.Name & " was changed to value " & MyCombo.Value
End Sub

Private Sub MyButton_Click()

    Dim BtnNum As Long

    BtnNum = Replace(MyButton.Name, "MyButton", "")

    MsgBox MyButton.Name & " is " & IIf(BtnNum Mod 2 = 0, "even", "odd")

End Sub

Note: When you enter the WithEvents you'll be able to select most events associated with that type of control.

Next, create a blank UserForm and add this code:

Option Explicit

Public MyEvents As New Collection

Private Sub UserForm_Initialize()

    Dim tmpCtrl As Control
    Dim CmbEvent As clsMyEvents
    Dim x As Long

    'Add some dummy data for the combo-boxes.
    Sheet1.Range("A1:A5") = Application.Transpose(Array("Red", "Yellow", "Green", "Blue", "Pink"))
    Sheet1.Range("B1:B5") = Application.Transpose(Array(1, 2, 3, 4, 5))
    Sheet1.Range("C1:C5") = Application.Transpose(Array(5, 4, 3, 2, 1))

    For x = 1 To 5
        'Add the control.
        Set tmpCtrl = Me.Controls.Add("Forms.ComboBox.1", "MyCombobox" & x)
        With tmpCtrl
            .Left = 10
            .Width = 80
            .Top = (x * 20) - 18 'You might have to adjust this spacing.  I just made it up.
            .RowSource = "Sheet1!" & Sheet1.Cells(1, x).Resize(5).Address
        End With

        'Attach the event.
        Set CmbEvent = New clsMyEvents
        Set CmbEvent.MyCombo = tmpCtrl
        MyEvents.Add CmbEvent

    Next x

    For x = 1 To 5
        Set tmpCtrl = Me.Controls.Add("Forms.CommandButton.1", "MyButton" & x)
        With tmpCtrl
            .Left = 100
            .Width = 50
            .Height = 20
            .Top = (x * 20) - 18
            .Caption = "Num " & x
        End With

        Set CmbEvent = New clsMyEvents
        Set CmbEvent.MyButton = tmpCtrl
        MyEvents.Add CmbEvent
    Next x

End Sub

Edit: I've updated to include code for a command button as well. When you change the value in a combobox it will tell you the name of the control and the value it was changed to. When you click a button it will tell you if the number on it is odd or even.