1

I have an applescript which creates a shortcut on a desktop to an executable on the file system. The excutable has the standard exec icon . Is it possible to change the icon to point to say an icns file ?

I've read you can do it using a third party program as mentioned in Change icon of folder with AppleScript?

but is it possible without using an external program to do this ?

This is my script

set source_file to (POSIX file "path to my exectuable")
tell application "Finder"
make new alias file at desktop to source_file
set name result to "My Shortcut"
end tell

Note: I can also create the same shortcut using ln -s command but in that I don't get any icon, its just a blank page symbol shortcut

Abbas
  • 3,144
  • 2
  • 25
  • 45

2 Answers2

2

Dealing with alias files like that is a bit of a pain, since the Finder seems to lose track of an alias file of an alias after you rename it (even though it is an alias). One solution would be to use some AppleScriptObj-C to set the icon before renaming the alias file, for example (Mojave):

use framework "Foundation"
use scripting additions

set sourceFile to (choose file)
tell application "Finder"
  set newAlias to (make new alias file at desktop to sourceFile) as alias
  my setIcon(newAlias)
  set name of newAlias to "My Shortcut"
end tell

to setIcon(fileRef)
  set iconImage to current application's NSImage's alloc's initWithContentsOfFile:"/System/Library/CoreServices/CoreTypes.bundle/Contents/Resources/AlertCautionIcon.icns" -- example image file
  current application's NSWorkspace's sharedWorkspace's setIcon:iconImage forFile:(POSIX path of fileRef) options:0
end setIcon
red_menace
  • 3,162
  • 2
  • 10
  • 18
  • This solution is working for HighSierra but for El Capitan, the icon is not changed. Any idea why ? – Abbas Mar 01 '19 at 09:22
0

The previous solution worked on the older OS-s, but on the new OS-s the icon of a Finder alias file gets custom icon only after changing the icon of its original file. It seems, it is a new behaviour of Finder.app. Here is a workaround:

-- script: Create Finder alias file with custom icon
-- written: by me, right now

use framework "Foundation"
use scripting additions

-- get source file (that is, original item)
set sourceFile to (choose file)

-- indicate custom icon's Posix payh
set iconFile to "/System/Library/CoreServices/CoreTypes.bundle/Contents/Resources/AlertCautionIcon.icns"

-- change icon of the original (source) file
set theImage to current application's NSImage's alloc()'s initWithContentsOfFile:iconFile
set ws to current application's NSWorkspace's sharedWorkspace()
ws's setIcon:theImage forFile:(POSIX path of sourceFile) options:0

-- make Finder alias file on desktop
tell application "Finder" to set aliasRef to (make new alias file at desktop to sourceFile) as text

delay 2 -- required (test other delay values)

-- remove original file's custom icon (that is, restore to defaults icon)
ws's setIcon:(missing value) forFile:(POSIX path of sourceFile) options:0
Robert Kniazidis
  • 1,760
  • 1
  • 7
  • 8
  • Are you talking about Ventura and later? – red_menace Apr 16 '23 at 19:24
  • Re: @red_menace, I tested on Catalina. The post owner reported that the old solution doesn't work from El Capitan. I confirm: on Catalina the old solution fails without errors, the icon is not changed. – Robert Kniazidis Apr 17 '23 at 06:04