How to reverse order of columns in tabular data using bash

Question

Given tabular output from some program in bash I would like to change order of colums printed. Assume number of columns might vary.

Sample input

Name  Surname   Age
Oli   Aaa       15
Boa   Bbb       25

Expected output

Age  Surname    Name
15   Aaa        Oli
25   Bbb        Boa

What I tried

It seems to me as an easy task when number of columns is known, but I don't know what to do when number of columns is just N. For 3 columns simple AWK script would do:

cat table.txt | awk '{print $3 $2 $1}' > reversed_table.txt

It would be good to achieve this using only POSIX-compliant tools.

Please do add your efforts which you have put in order to solve your own problem and let us know then. — RavinderSingh13, Oct 09 '19 at 12:43

KamilCuk · Accepted Answer · 2019-10-09T13:51:28.967

4

using only POSIX-compliant tools

awk is posix.

but I don't know what to do when number of columns is just N

Now that's easy. So first, awk is really flexible. The awk '{ i=5; print $i; } will print the 5th column, just like that.

Second you can get the number of columns with NF.

Now, it's just writing a simple for loop and iterating from the NF to first argument and viola!

 awk '{ for(i = NF; i >= 1; --i) printf "%s", $i "\t"; printf "\n" }'

A bit better version without a trailing tabulator:

 awk '{ for(i = NF; i >= 1; --i) printf "%s", $i (i==1 ? "" : OFS); print ""; }'

edited Oct 09 '19 at 13:51

answered Oct 09 '19 at 12:52

KamilCuk

120,984
8
59
111

4

maybe a style choice but why not `i>0` instead. Also, `print ""` should do. However, you'll have a dangling tabs at the end of lines.`printf "%s", $i (i==1?ORS:OFS)` is better. – karakfa Oct 09 '19 at 13:46
FWIW I prefer `printf "%s%s", $i, (i>1?OFS:ORS)` - 2 strings so 2 `%s`s and the ORS coming after the OFS both just feel more "right". – Ed Morton Oct 09 '19 at 14:57

RavinderSingh13 · Answer 2 · 2019-10-09T15:45:44.207

Here is a Generic solution. Where we have 2 variables named swap1 and swap2, in swap one mention keep mapping with swap2 eg--> we want to exchange 3rd field to 5th field AND 4th field with 6th field. Likewise we can have a number of digits in it(I have considered a scenario where we want to exchange 3rd field to 5th field AND 4th field to 6th field).

swap1 --> 3    4
          |    |
          |    |
          |    |
swap2 --> 5    6

Following is the code:

awk -v swap1="3,4"  -v swap2="5,6" '
BEGIN{  
  num=split(swap1,field1,",")
  num1=split(swap2,field2,",")
  for(i=1;i<=num;i++){
    array1[field1[i]]=i
  }
}
FNR==1{
  print
  next
}
{
  for(i=1;i<=NF;i++){
    if(i in array1){
      tmp=$field1[array1[i]]
      $field1[array1[i]]=$field2[array1[i]]
      $field2[array1[i]]=tmp
    }
  }
}
1
'  Input_file  | column -t

@Ed Morton, Hi Ed sir, I have come up with this generic approach(IMHO :) ), May I ask you your thought sir on same if you wouldn't mind sir, how it looks to you? — RavinderSingh13, Oct 09 '19 at 15:41

score 1 · Answer 3 · answered Oct 10 '19 at 08:18

1

This might work for you (GNU sed and rev):

sed 's/.*/echo "&" | rev/e;s/\S\+/$(echo "&"|rev)/g;s/.*/echo "&"/e' file

Reverse each line and re-reverse each separate word within the line.

answered Oct 10 '19 at 08:18

potong

55,640
6
51
83

Claes Wikner · Answer 4 · 2019-10-11T10:04:11.377

0

awk '{use = $NF;$NF = "";print use,$2,$1}' OFS="\t" file

Age Surname Name
15  Aaa     Oli
25  Bbb     Boa

I looked into this one: Printing everything except the first field with awk

edited Oct 11 '19 at 10:04

answered Oct 10 '19 at 22:10

Claes Wikner

1,457
1
9
8

How to reverse order of columns in tabular data using bash

Sample input

Expected output

What I tried

4 Answers4