2

I'm working on a d3d application and i would like to compile my .hlsl shaders during to build using cmake. I have no idea where to start.

this is my current CMakeLists.txt

cmake_minimum_required(VERSION 3.20)
project(Direct3DTut)

set(CMAKE_CXX_STANDARD 17)

add_executable(${PROJECT_NAME} WIN32
                WinMain.cpp Window.cpp MessageHandler.cpp Graphics.cpp
                Keyboard.cpp Mouse.cpp
                Utils.cpp)

set(LIBS d3d11 D3DCompiler)
target_link_libraries(${PROJECT_NAME} ${LIBS})
Barbapapoy
  • 25
  • 6
  • Just list ``.hlsl`` files among source files for `add_executable` call. Visual Studio will automatically compile them. – Tsyvarev Feb 28 '22 at 19:48
  • I'm using Clion but the msvc compiler so i guess it work the same? Where can i find the ouput of the compilation? – Barbapapoy Feb 28 '22 at 20:15

1 Answers1

6

I use this pattern for CMake shaders that works with both Ninja and the MSVC generators.

# Build HLSL shaders
add_custom_target(shaders)

set(HLSL_SHADER_FILES VertexShader.hlsl PixelShader.hlsl)

set_source_files_properties(VertexShader.hlsl PROPERTIES ShaderType "vs")
set_source_files_properties(PixelShader.hlsl PROPERTIES ShaderType "ps")
set_source_files_properties(${HLSL_SHADER_FILES} PROPERTIES ShaderModel "4_0")

foreach(FILE ${HLSL_SHADER_FILES})
  get_filename_component(FILE_WE ${FILE} NAME_WE)
  get_source_file_property(shadertype ${FILE} ShaderType)
  get_source_file_property(shadermodel ${FILE} ShaderModel)
  add_custom_command(TARGET shaders
                     COMMAND fxc.exe /nologo /Emain /T${shadertype}_${shadermodel} $<IF:$<CONFIG:DEBUG>,/Od,/O1> /Zi /Fo ${CMAKE_BINARY_DIR}/${FILE_WE}.cso /Fd ${CMAKE_BINARY_DIR}/${FILE_WE}.pdb ${FILE}
                     MAIN_DEPENDENCY ${FILE}
                     COMMENT "HLSL ${FILE}"
                     WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
                     VERBATIM)
endforeach(FILE)

...

add_dependencies(${PROJECT_NAME} shaders)

I use this in my DirectX Tool Kit tutorials. You can also see the rest of the CMake on directx-vs-templates.

Chuck Walbourn
  • 38,259
  • 2
  • 58
  • 81
  • It seems like the command gets evaluated to `fxc.exe /nologo /Emain /T${shadertype}_${shadermodel} "" /Zi /Fo ${CMAKE_BINARY_DIR}/${FILE_WE}.cso /Fd ${CMAKE_BINARY_DIR}/${FILE_WE}.pdb ${FILE}` in release mode with the empty double quotes in the command. That fails to run. Any ideas why this happens and how one can avoid this? – SunnyMonster May 08 '22 at 00:17
  • Interesting. ``DXC.EXE`` tolerates the ``""``, but FXC doesn't. – Chuck Walbourn May 08 '22 at 07:37
  • The best solution is to use ``$,/Od,/O1>`` for FXC and use ``$,/Od,/O3>`` for DXC – Chuck Walbourn May 08 '22 at 07:43